IncludeGenerator %occInclude

/// Интерфейс для выгрузки в csv
/// Использование - отнаследоваться и вызвать
/// <example> d ..CSVExport()</example>
/// Формат выгрузки: Первая строка - Имена полей через точку запятой
/// Последующие строки - Данные по полям через точку запятой, каждая запись с новой строки
Class CSV.Adaptor [ Abstract ] {

/// Основной метод, ради которого весь сыр-бор
ClassMethod CSVExport() [ CodeMode = generator ] {
 #; проверки и защита
 Q:$$$CLASSabstract($$$gDEF,%class) $$$OK
 Q:'$$$classIsPersistent(%class) $$$OK  
  
 #;Готовим выражение для Select [fields...] Into [vars...]
 s fields="",vars="",count= 0  
 s prop="" for { s prop=$$$defMemberNext(%class,$$$cCLASSproperty,prop) Q:prop=""  
	if $$$PROPtransient($$$gDEF,%class,prop) continue ;возможно нужны еще проверки
    s count=count+ 1  ;количество свойств
 	s:fields'="" fields=fields_"," ;список полей через запятую  
	s:vars'="" vars=vars_"," ;список переменных через запятую
    s field=prop, sqlfld=$$$PROPsqlfieldname($$$gDEF,%class,prop)
    s:sqlfld'="" field=sqlfld ;переопределяем имя свойства именем поля, если необходимо
    s fields=fields_field, vars=vars_":fld"_count ;собираем списки
 }

 #;Разбираемся с именем таблицы - кто нить знает "правильный" способ?
 #; тут м.б проблемы из-за настройки, разрешающей точку в имени таблицы
 s sqltable=$$$CLASSsqltablename($$$gDEF,%class)
 s deep=$l(%class,"."), package=$p(%class,".", 1 ,deep- 1 ), class=$p(%class,".",deep) 
 s:sqltable'="" class=sqltable ;Вот тут проблемы
 s package=$tr(package,".","_")
 #;Контролируем пакет User
 s firstPackage=$p(%class,".") s:firstPackage="User" package="SQL"_package
 s table=package_"."_class

 #; Отладка
 w !,"CSVExport: Select "_fields
 w !,"CSVExport: INTO "_vars
 w !,"CSVExport: FROM "_table

 #; Пишем в код
 s %code= 0 
 #;выводим заголовок csv
 $$$GENERATE("  w """_$tr(fields,",",";")_""" ")	 
 #;генерируем запрос, имя курсора в классе д.б. уникально 
 $$$GENERATE("  &sql(DECLARE csvrs CURSOR FOR ")
 $$$GENERATE("  Select "_fields_" INTO "_vars_" FROM "_table_")  ")
 $$$GENERATE("  &sql(OPEN csvrs) ")
 $$$GENERATE("  for { &sql(FETCH csvrs) Q:SQLCODE ")
 $$$GENERATE("  	w ! ")
 for fi= 1 : 1 :count {
   if fi> 1  $$$GENERATE("	  w "";""  ")	 
   $$$GENERATE("	  w $tr(fld"_fi_",$c(13,10,59),$c(32)) ")
 }
 $$$GENERATE("  } ")
 $$$GENERATE("  &sql(CLOSE csvrs) ")
 $$$GENERATE("  Q $$$OK " )
 w ! zw %code
 Q $$$OK
}

}