select ##class(<имя_класса>).<имя_метода>(<список_параметров>) from tmp.test
...
select * from tmp.test where ##class(<имя_класса>).<имя_метода>(<список_параметров>)= 1 

/// <b>Список работников</b>
/// <table>
/// <tr>
/// <td><b>Id</b></td>
/// <td><i>ИД работы</i></td>
/// </table>
ClassMethod AllMember(Id As %String) As %String [ SqlProc ]
{
	s Member=""
	s dlm=", "
	s sql="Select Member->Name as Memb From wrk.Stage Where Job=? Group by Member Order by Member->Prg desc,Member->Name"
	s ors=##class(%ResultSet).%New("%DynamicQuery:SQL")
	s ok=ors.Prepare(sql)
	s:ok ok=ors.Execute(Id)
	s i= 0 
	while ors.Next() {
		s:ors.Get("Memb")'="" $p(Member,dlm,$i(i))=ors.Get("Memb")
	}
	d ors.Close()
	q Member
}

/// Построение запроса для отображения таблицы
Method CrtSQL(Output tSC As %Status, pInfo As %ZEN.Auxiliary.QueryInfo) As %ResultSet
{
	Set tRS = ""
	
	Set tSC = $$$OK
	Set tSELECT = "ID,Name,"
	Set tSELECT = tSELECT_"wrk.Job_AllMember(ID) as Member,"
	Set tSELECT = tSELECT_"dEnd as Brk,"
	Set tSELECT = tSELECT_"wrk.Plan_KvrToStr(Plan->ID) as Kvartal,"
	Set tSELECT = tSELECT_"wrk.Job_Ok(ID) as Ok"
	Set tFROM = "wrk.Job as a"
	Set tWHERE = ""
	Set tORDER = "dCreate desc,Member"
	// строим критерии отбора по фильтрам
	If $g(pInfo.filters("Name"))'="" {
		Set tWHERE = tWHERE_"Upper(Name) [ Upper('"_pInfo.filters("Name")_"') "
	}
	If $g(pInfo.filters("Member"))'="" {
		Set:tWHERE'="" tWHERE=tWHERE_" AND "
		Set tWHERE=tWHERE_"wrk.Job_AllMember(ID)['"_ pInfo.filters("Member")_"'"
	}
	If $g(pInfo.filters("Ok"))'="" {
		Set:tWHERE'="" tWHERE=tWHERE_" AND "
		s ok="<>"
		s:pInfo.filters("Ok")="Да" ok="="
		Set tWHERE=tWHERE_"wrk.Job_Ok(ID)"_ok_"'Да'"
	}
	Set sql = "SELECT " _ tSELECT _ " FROM " _ tFROM
	Set:tWHERE'="" sql = sql _ " WHERE " _tWHERE
	Set:tORDER'="" sql = sql _ " ORDER BY " _tORDER
	Set tRS = ##class(%ResultSet).%New()
	Set tSC = tRS.Prepare(sql)
	Set pInfo.queryText = sql
	Quit tRS
}

ERR>w ##class(wrk.Job).AllMember( 9 )
Разуваева З.М., Сазонова Т.М.
ERR>