Добрый день, krvsa!
Приведу фрагменты кода где использую и создаю ресурсы.
Клиент.
<hmenu id="MainMenu"
onshowHelp="zenPage.showHelp(help);"
help="Top">
<menu caption="Система" id="menuSystem" resource="User_SYS" layout="vertical">
<menuItem id="mnuRegUser"
caption="Реєстрація користувачів"
link="WEBFORM.frmRegUsers.cls"
image="images/regusers.png"
title="Реєстрація користувачів для роботи в системі"
resource="Admin_Total"
/>
<menuItem id="mnuPeople"
caption="Фізичні особи"
link="WEBFORM.frmPeople.cls"
image="images/users.png"
title="Довідник фізичних осіб"
resource="Individual"
/>
...
Программа, используя которую можно создавать пользователей, роли и ресурсы.
sysWork ;
//создание нового пользователя
NewUser(oldLog,log,pwd,id,idGr,managerSys)
s PeopleID=##class(DATA.HUMAN.People).%OpenId(id)
s FullName=PeopleID.Man.Surname_" "_PeopleID.Man.Name_" "_PeopleID.Man.Patronymic
d PeopleID.%Close()
s Gr=##class(DATA.SHARED.GroupUserSys).%OpenId(idGr)
s NameGr=Gr.Name
d Gr.%Close()
s namespace=$ZNSpace
zn "%SYS"
s prop="",sysUser=""
s sysUser=##Class(Security.Users).Get(oldLog,.prop)
if sysUser=1
{
s roles="%DB_%DEFAULT,%DB_CACHESYS,"_NameGr
if managerSys {s roles=roles_",%Manager"}
s prop("Roles")=roles
s prop("Password")=pwd
s prop("FullName")=FullName
s sysUser=##Class(Security.Users).Modify(oldLog,.prop)
}
else
{
s sysUser=##Class(Security.Users).%New()
s sysUser.Name=log
s sysUser.Password=pwd
s sysUser.FullName=FullName
do sysUser.Roles.Clear()
do sysUser.Roles.Insert("%DB_%DEFAULT")
do sysUser.Roles.Insert("%DB_CACHESYS")
if managerSys {do sysUser.Roles.Insert("%Manager")}
do sysUser.Roles.Insert(NameGr)
d sysUser.%Save()
}
zn namespace
&sql(GRANT * ON * TO *)
q
//удаление пользователя
DeleteUser(id)
;DO $SYSTEM.Security.Login("_SYSTEM","SYS")
s cls=##class(DATA.SYSTEM.USERS).%OpenId(id)
if cls'=""
{ s login=cls.Login
d cls.%Close()
zn "%SYS"
d ##Class(Security.Users).Delete(login)
}
q
//удаление роли
DeleteRoles(id)
zn "%SYS"
do ##Class(Security.Roles).Delete(id)
q
//создание роли
CreateRoles(Name,Opis,SpisRes)
zn "%SYS"
if (##Class(Security.Roles).Exists(Name))
{
s Properties("Resources")=""
s Properties("Resources")=SpisRes
do ##Class(Security.Roles).Modify(Name,.Properties)
}
else
{
s res=##Class(Security.Roles).%New()
d res.Create(Name,Opis,SpisRes,) ; создает роль с ресурсами(разделитель запятая)
d res.%Save()
}
q
//редактирование роли
EditRoles(oldid,id)
zn "%SYS"
do ##Class(Security.Roles).Copy(oldid,id,oldid)
do ##Class(Security.Roles).Delete(oldid)
q
//удаление ресурса
DeleteResources(id)
zn "%SYS"
do ##Class(Security.Resources).Delete(id)
q
//создание ресурса
CreateResources(Name,Opis)
zn "%SYS"
s res=##Class(Security.Resources).%New()
s res.Name=Name
s res.Description=Opis
d res.%Save()
q
CreateAllResources
s namespace=$ZNSpace
zn "%SYS"
Set rset = ##class(%ResultSet).%New("DATA.SHARED.ResSys:ByName")
Do rset.Execute()
//заполняем созданый список ресурсов
While (rset.Next()) {
s res=##Class(Security.Resources).%New()
s res.Name=rset.Data("Name")
s res.Description=rset.Data("Opisanie")
d res.%Save()
}
zn namespace
q
СreateResourcesFrom()
;дополнение списка ресурсов
s namespace=$ZNSpace
zn "%SYS"
s i=0
for {
set i=i+1
set option=$CASE(i,1:"Individual^Фізічна особа",
2:"Juridical^Юридична особа",
3:"Admin_Total^Адміністратор системи",
4:"Admin_DB^Адміністратор бази даних",
5:"User_SYS^Загальний користувач",
6:"Individual_Edit^Редагування Фізічної особи",
7:"Juridical_Edit^Редагування Юридичної особи",
8:"Total_Edit^Редагування",
9:"User_GO^Загальний користувач ОСАГО",
10:"Admin_GO^Адміністратор бази данних ОСАГО",
11:"%System_CallOut^%System_CallOut",
12:"%All^%All",
:"close")
q:option="close"
s NamRes=$p(option,"^"),NamOpis=$p(option,"^",2)
i NamRes'="" {
s res=##Class(Security.Resources).Exists(NamRes)
i 'res {
s sres=##Class(Security.Resources).%New()
s sres.Name=NamRes
s sres.Description=NamOpis
d sres.%Save()
}
zn namespace
Set rset = ##class(%ResultSet).%New("DATA.SHARED.ResSys:SerchName")
Do rset.Execute(NamRes)
i 'rset.Next() {
s rres=##Class(DATA.SHARED.ResSys).%New()
s rres.Name=NamRes
s rres.Opisanie=NamOpis
d rres.%Save()
}
zn "%SYS"
}
}
q 1
Пример вызова программы.
/// Формирование полного набора ресурсов
Method СreateResourcesFrom() [ ZenMethod ]
{
j СreateResourcesFrom^sysWork()
h 1
&js<zenPage.gotoPage('WEBFORM.frmAllResSys.cls');>
q
}
Создание роли.
Class WEBFORM.frmCardGroup Extends WEBFORM.Template.TemplateCard
{
/// Имя приложения, которому принадлежит эта страница.
Parameter APPLICATION = "WEBFORM.Application";
/// Отображаемое имя для нового приложения.
Parameter PAGENAME;
/// Домен, используемый для локализации.
Parameter DOMAIN;
Property objID As %ZEN.Datatype.integer(ZENURL = "ID") [ InitialExpression = 1 ];
/// Этот блок Style содержит определение CSS стиля страницы.
XData Style
{
<style type="text/css">
</style>
}
/// Этот XML блок описывает содержимое этой страницы.
XData mainPane [ XMLNamespace = "http://www.intersystems.com/zen" ]
{
<pane xmlns="http://www.intersystems.com/zen" title="">
<dataController id="source" modelClass="WEBFORM.DataModel.GroupUserSys" modelId="#(%url.ID)#"/>
<fieldSet label="Картка ролі користувача" labelStyle="font-size: 1.5em; text-align: center;">
<form id="idForm" align="center" valign="middle" controllerId="source">
<text label="Назва ролі:" id="Name"
name="Name" size="50"
required="true"
requiredMessage="не заповнено"
dataBinding="Name"
/>
</form>
</fieldSet>
<hgroup align="right">
<button align="right" caption="Зберегти" onclick="zenPage.saveItem();"/>
<spacer width="40"/>
<button align="right" caption="Вихід" onclick="zenPage.ExitForm();"/>
</hgroup>
<text label="ID:" id="objid" value="#(%url.ID)#" size="4" hidden="true"/>
</pane>
}
/// сохранение записи
Method saveItem() [ Language = javascript ]
{
var form = zenPage.getComponentById('idForm');
form.save();
var name = zenPage.getComponentById('Name').getProperty('value');
this.CreateRoles(name);
self.close();
}
/// создание роли
ClassMethod CreateRoles(id) [ ZenMethod ]
{
j CreateRoles^sysWork(id,id,"")
Quit
}
/// закрываем окно
Method ExitForm() [ ZenMethod ]
{
&js<self.close();>
}
}
создание списка ресурсов для роли.
Class WEBFORM.frmCardPermissionGroup Extends WEBFORM.Template.TamplateObject
{
/// Имя приложения, которому принадлежит эта страница.
Parameter APPLICATION = "WEBFORM.Application";
/// Отображаемое имя для нового приложения.
Parameter PAGENAME;
/// Домен, используемый для локализации.
Parameter DOMAIN;
Property objID As %ZEN.Datatype.integer(ZENURL = "ID") [ InitialExpression = 1 ];
/// Этот блок Style содержит определение CSS стиля страницы.
XData Style
{
<style type="text/css">
</style>
}
/// Этот XML блок описывает содержимое этой страницы.
XData Contents [ XMLNamespace = "http://www.intersystems.com/zen" ]
{
<page xmlns="http://www.intersystems.com/zen" title="" dragAndDrop="true">
<hgroup align="center">
<vgroup valign="top">
<titleBox title="Доступні ресурси"/>
<spacer height="2"/>
<listBox id="DostMenu" listWidth="400px" listHeight="570px"
dragEnabled="true" dropEnabled="true"
onafterdrag="zenPage.afterDrag(zenThis,dragData);">
</listBox>
</vgroup>
<spacer width="10"/>
<vgroup valign="top">
<titleBox title="Вибрані ресурси"/>
<spacer height="2"/>
<listBox id="SelectMenu" listWidth="400px" listHeight="570px"
dragEnabled="true" dropEnabled="true"
onafterdrag="zenPage.afterDrag(zenThis,dragData);">
</listBox>
</vgroup>
</hgroup>
<hgroup align="center">
<button align="center" caption="Зберегти" onclick="zenPage.saveItem();"/>
<spacer width="40"/>
<button align="center" caption="Вихід" onclick="zenPage.ExitForm();"/>
</hgroup>
<text label="ID:" id="objid" value="#(%url.ID)#" size="4" hidden="true"/>
</page>
}
/// сохранение записи
Method saveItem() [ Language = javascript ]
{
var menu= zenPage.getComponentById('SelectMenu');
var itemCount=menu.getOptionCount();
var getStringItem = new Array();
for (i=0;i<itemCount;i++)
{
getStringItem[i]=menu.getOptionValue(i)+'^'+menu.getOptionText(i);
}
this.savePermissionGroup(getStringItem);
}
Method savePermissionGroup(listItem As %ListOfDataTypes) [ ZenMethod ]
{
s cl=##class(DATA.SHARED.GroupUserSys).%OpenId(..objID)
s name=cl.Name
d cl.SelectMenu.Clear()
s res=""
if (listItem'="")
{
for i=1:1:listItem.Count()
{
s clItem=##class(DATA.SHARED.ParamSaveGroup).%New()
s clItem.value=$p(listItem.GetAt(i),"^",1)
s clItem.text=$p(listItem.GetAt(i),"^",2)
d cl.SelectMenu.Insert(clItem)
s res=res_clItem.value_":U,"
}
}
s res=$e(res,1,$l(res)-1)
d cl.%Save()
j CreateRoles^sysWork(name,name,res)
&js<alert('Ресурси записані!');>
}
Method loadPermissionGroup() [ ZenMethod ]
{
//открываем класс где определены доступные пункты меню для группы
s cl=##class(DATA.SHARED.GroupUserSys).%OpenId(..objID)
//создаем стартовый список пунктов меню
s clDostMenu=##class(%ListOfDataTypes).%New()
Set rset = ##class(%ResultSet).%New("DATA.SHARED.ResSys:ByName")
Do rset.Execute()
//заполняем созданый список ресурсов
While (rset.Next())
{
set option=rset.Data("Name")_"^"_rset.Data("Opisanie")
d clDostMenu.Insert(option)
}
//очищаем списоки
&js<var compSelect = zenPage.getComponentById('SelectMenu');
var compDost = zenPage.getComponentById('DostMenu');
if (compSelect){compSelect.resetOptions()};
if (compDost){compDost.resetOptions()};>
Set tComp = %page.%GetComponentById("SelectMenu")
If $IsObject(tComp)
{
for i=1:1:cl.SelectMenu.Count()
{
s clItem=##class(DATA.SHARED.ParamSaveGroup).%New()
s clItem=cl.SelectMenu.GetAt(i)
// заполняем список выбранных пунктов меню
&js<
var comp = zenPage.getComponentById('SelectMenu');
if (comp)
{
comp.appendOption('#(clItem.value)#','#(clItem.text)#');
}
>
//убираем из списка доступных пунктов меню выбранные
for j=1:1:clDostMenu.Count()
{
s iDelete=clDostMenu.Find(clItem.value_"^"_clItem.text)
d clDostMenu.RemoveAt(iDelete)
}
}
}
//заполняем список доступных пунктов меню
for j=1:1:clDostMenu.Count()
{
s clDostItem=clDostMenu.GetAt(j)
s value=$p(clDostItem,"^",1)
s text=$p(clDostItem,"^",2)
&js<
var comp = zenPage.getComponentById('DostMenu');
if (comp)
{
comp.appendOption('#(value)#','#(text)#');
}
>
}
}
/// закрываем окно
Method ExitForm() [ ZenMethod ]
{
&js<self.close();>
}
Method afterDrag(listBox, dragData) [ Language = javascript ]
{
if (dragData.targetComponent.isOfType('listBox')) {
// ignore drag onto ourselves
if (dragData.targetComponent != listBox) {
if (dragData.sourceItem >= 0) {
listBox.removeOption(dragData.sourceItem);
}
}
}
}
/// This client event, if present, is fired when the page is loaded.
Method onloadHandler() [ Language = javascript ]
{
this.loadPermissionGroup();
}
}
Создание нового пользователя
Class WEBFORM.frmCardRegUser Extends WEBFORM.Template.TemplateCard
{
/// Имя приложения, которому принадлежит эта страница.
Parameter APPLICATION = "WEBFORM.Application";
/// Отображаемое имя для нового приложения.
Parameter PAGENAME;
/// Домен, используемый для локализации.
Parameter DOMAIN;
Property objID As %ZEN.Datatype.integer(ZENURL = "ID") [ InitialExpression = 1 ];
Property paramSave As %Integer [ InitialExpression = 0 ];
/// Этот блок Style содержит определение CSS стиля страницы.
XData Style
{
<style type="text/css">
</style>
}
/// Этот XML блок описывает содержимое этой страницы.
XData mainPane [ XMLNamespace = "http://www.intersystems.com/zen" ]
{
<pane xmlns="http://www.intersystems.com/zen" title="">
<dataController id="sourceUsers"
modelClass="WEBFORM.DataModel.Users" modelId="#(%url.ID)#"/>
<fieldSet label="Реєстраційна картка користувача" labelStyle="font-size: 1.5em; text-align: center;">
<vgroup id="groupRight" width="100%" valign="top">
<spacer height="10"/>
<html id="error" align="center" enclosingStyle="color:red;"></html>
<form id="formBasic" align="center" width="500px">
<group align="center">
<spacer height="40"/>
<dataCombo label="Фізична особа" id="idSurname" name="idSurname" size="40"
dropdownWidth="400"
editable="true"
searchKeyLen="20"
comboType="button"
buttonCaption="Пошук"
buttonTitle="Пошук за прізвищем"
sql="SELECT %ID,Man_Surname,Man_Surname _' '_ Man_Name _' '_ Man_Patronymic,
Man_BirthDay FROM DATA_HUMAN.People WHERE Man_Surname %STARTSWITH ? ORDER BY Man_Surname"
sqlLookup="SELECT Man_Surname,Man_Surname _' '_ Man_Name _' '_ Man_Patronymic,
Man_BirthDay FROM DATA_HUMAN.People WHERE %ID=? ORDER BY Man_Surname"
unrestricted="true"
columnHeaders="Прізвище ім'я та по батькові, День народження"
displayColumns="3,4"
choiceColumn="2"
valueColumn="1"
maxRows="100"
required="false"
onchange="zenPage.changeEnterprise();"
/>
<spacer height="10"/>
<dataCombo id="idGruppa"
size="30"
comboType="button"
buttonCaption="Група ресурсів"
label="Групи системних ресурсів"
name="idGruppa"
editable="true"
choiceColumn="2"
valueColumn="1"
displayColumns="2"
dropdownWidth="25.0em"
dropdownHeight="auto"
searchKeyLen="5"
sql="SELECT %ID,Name FROM DATA_SHARED.GroupUserSys ORDER BY Name"
sqlLookup="SELECT Name FROM DATA_SHARED.GroupUserSys WHERE %ID = ? ORDER BY Name"
columnHeaders="Групи системних ресурсів"
cached="true"
required="false"
unrestricted="true"
/>
<text label="Логін:" id="Login" name="Login" size="40"
required="true"/>
<password label="Пароль:" id="Password1" name="Password1" size="40"
required="true"/>
<password label="ще раз:" id="Password2" name="Password2" size="40"
required= "true"/>
<checkbox id="manager"
label="Дозволено добавляти нових користувачів, та редагувати права доступу існуючих"
/>
<checkbox id="ShowAllRecord"
label="Дозволено перегляд усіх записів"
/>
</group>
</form>
</vgroup>
</fieldSet>
<spacer height="40"/>
<hgroup align="right">
<button align="right" caption="Реєстрація" onclick="zenPage.Registration();"/>
<spacer width="40"/>
<button align="right" caption="Вихід" onclick="zenPage.ExitForm();"/>
</hgroup>
</pane>
}
Method changeEnterprise() [ Language = javascript ]
{
var checkUser=zenPage.getComponentById('idSurname');
var id=checkUser.getProperty('value');
var countWorkPlace=this.systemIStartSetup(id);
if (countWorkPlace==0) alert('Увага! Для даної фізичної особи необхідно додати місце роботи!');
}
Method systemIStartSetup(id) As %Integer [ ZenMethod ]
{
s recordCount=0
set rs=##class(%ResultSet).%New()
set rs.ClassName="DATA.PERSONNELDEPARTMEN.Workplace"
set rs.QueryName="GetWorkplaceByPeopleID"
set sc=rs.Execute(id)
If $$$ISOK(sc)
{
while rs.%Next()
{
s ..paramSave=1
s recordCount=recordCount+1
}
}
q recordCount
}
Method ExitForm() [ ZenMethod ]
{
///закрываем окно
&js<self.close();>
}
/// Регистрация
Method Registration() [ ZenMethod ]
{
if ..paramSave=0
{
&js<alert('Увага! Для даної фізичної особи необхідно додати місце роботи!');>
q
}
if ($ROLES["%All")||($ROLES["%Manager")
{
if (..objID="")
{
set user=##class(DATA.SYSTEM.USERS).%New()
}
else
{
set user=##class(DATA.SYSTEM.USERS).%OpenId(..objID)
}
set p1 = ..%GetValueById("Password1")
set p2 = ..%GetValueById("Password2")
if p1'=p2 {
&js<zenPage.getComponentById('error').setContent("Ви ввели два різних пароля!");>
quit
}
#; проверка на наличие пустых полей
if '(..CheckValue()){
&js<zenPage.getComponentById('error').setContent("Заповніть всі поля!");>
quit
}
set oldLogin=user.Login
set login = ..%GetValueById("Login")
;s ^a(1)=oldLogin_","_login_","_(oldLogin '= login)
#; если введенный Login существует – ошибка
if (..objID="")
{
set pId = ##class(DATA.SYSTEM.USERS).FindPersonal(login)
if (pId '= "") {
&js<zenPage.getComponentById('error').setContent("Користувач с таким логіном уже існує! Введіть інший.");>
quit
}
}
if oldLogin'="",oldLogin'=login
{
&js<zenPage.getComponentById('error').setContent("Заборонено редагувати логін в цьому режимі! Потрібно вилучити користувача.");>
Do %page.%SetValueById("Login",user.Login)
quit
}
#; новый класс DATA.SYSTEM.USERS
//Set text=$ZCONVERT(p1,"O","UTF8")
//Set pasw=$SYSTEM.Encryption.Base64Encode(text)
//set user.Password=pasw
Set text=$ZCONVERT(p1,"O","UTF8")
Set pasw=$SYSTEM.Encryption.Base64Encode(text)
set user.Password=pasw
set user.Login = login
//set user.Password = p1
d user.PeopleSetObjectId(..%GetValueById("idSurname"))
d user.GrNameSetObjectId(..%GetValueById("idGruppa"))
//пользователю добавляется роль %Manager для возможности управления пользователями в системе
s user.ManagerSys=..%GetValueById("manager")
s user.ShowAllRecord=..%GetValueById("ShowAllRecord")
d user.%Save()
&js<var formB = zenPage.getComponentById('formBasic');
var error = zenPage.getComponentById('error');
error.setProperty('enclosingStyle',"color:green;")
error.setContent("Реєстрація завершена успішно!");
>
//добавляем данного пользователя в пользователи Cache'
j NewUser^sysWork(oldLogin,login,p1,..%GetValueById("idSurname"),..%GetValueById("idGruppa"),..%GetValueById("manager"))
}
else
{
&js<alert("У вас недостатньо превілегій для даної операції. Зверніться до 'Адміністратора системи'");>
}
quit
}
/// Проверка всех полей ввода
Method CheckValue() As %ZEN.Datatype.boolean [ ZenMethod ]
{
set p1 = ..%GetValueById("Password1")
set login = ..%GetValueById("Login")
set surname = ..%GetValueById("idSurname")
set priorit = ..%GetValueById("idGruppa")
if (login="")||(surname="")||(p1="")||(priorit="")
{
quit 0
}
quit 1
}
ClassMethod LoadUser(pForm As %ZEN.Component.form, pID As %ZEN.Datatype.string) [ ZenMethod ]
{
set user=##class(DATA.SYSTEM.USERS).%OpenId(pID)
if user'="" {
Do %page.%SetValueById("Login",user.Login)
set ent = user.People
if ent'="" {Do %page.%SetValueById("idSurname",ent.%Id())}
set ent = user.GrName
if ent'="" {Do %page.%SetValueById("idGruppa",ent.%Id())}
Do %page.%SetValueById("manager",user.ManagerSys)
Do %page.%SetValueById("ShowAllRecord",user.ShowAllRecord)
}
}
Method %OnAfterCreatePage() As %Status
{
If (..objID '= "") {
#; load contents of given object into form
Set tForm = ..%GetComponentById("formBasic")
Do ..LoadUser(tForm,..objID)
}
Quit $$$OK
}
}
