ClassMethod Glo2XML(gloindex,tab As %String)
{
	if '$d(tab) {
		s tab = ""
		w "<?xml version=""1.0"" encoding=""utf-8""?>",!
	}
	q:$g(gloindex)="" ""
	w tab,"<node>",!
	// Индекс:
	s index = $zcvt($e($p(gloindex,"(",2),1,*-1),"O","XML")
	w tab,$c(9),"<index>"_index_"</index>",!
	// Данные:
	if $d(@gloindex)'[ 0  {
		s data = $g(@gloindex)
		s:$lv(data) data = $lts(data,, 1 )
		s data = $zcvt(data,"O","XML")
		w tab,$c( 9 ),"<data>"_data_"</data>",!
	}
	// Подузлы
	if $d(@gloindex)>= 10  {
		s key = ""
		f  {
			s key = $o(@gloindex@(key))
			q:key=""
			if $e(gloindex,*)=")" {
				s nextGloIndex = $e(gloindex, 1 ,*- 1 )_","""_key_""")"
			} else {
				s nextGloIndex = gloindex_"("""_key_""")"
			}
			d ..Glo2XML(nextGloIndex,tab_$c( 9 ))
		}
	}
	w tab,"</node>",!
	q
}

<?xml version="1.0" encoding="utf-8"?>
<node>
        <index></index>
        <data> 231 </data>
        <node>
                <index>"0"</index>
                <data> 51 </data>
        </node>
        <node>
                <index>"50"</index>
                <data> 350306 </data>
                <node>
                        <index>"50","1"</index>
                        <data>!!!!!!!!!!!!!!!! 0022 </data>
                        <node>
                                <index>"50","1","3"</index>
                                <data>!!!!!!!!!!!!!!!! 00 </data>
                        </node>
                </node>
        </node>
        <node>
                <index>"51"</index>
                <data> 349138 </data>
                <node>
                        <index>"51","1"</index>
                        <node>
                                <index>"51","1","3"</index>
                                <data> 349138 </data>
                        </node>
                </node>
        </node>
</node>