ПожалуйстаClass test.task [ Abstract ]
{

ClassMethod Test(h = 2)
{
  #dim ex As %Exception.AbstractException
  
  ##; статусы подзадач
  s s(-1)="удалена"
  s s(0)="выполняется"
  s s(1)="выполнена"

  ##; имена наших ресурсов (aka подзадач)
  s n(1)="Задача1"
  s n(2)="Задача2"

  ##; общие данные для теста
  s ^tmp(n(1),1)="а"
  s ^tmp(n(1),2)="б"
  s ^tmp(n(1),3)="в"
  s ^tmp(n(2),4)="г"
  s ^tmp(n(2),5)="д"
  s ^tmp(n(2),6)="е"
  
  try{

    ##; создаём ресурсы и подзадачи
    f i=1,2 {
      d $system.Event.Create(n(i))
      j ..SubTask(n(i),h)
    }
    
    ##; выдаём текущий статус подзадач
    ##; ждём завершения всех подзадач
    s c=0
    while (c<2) {
      f i=1,2 {
        s r(i)=$system.Event.WaitMsg(n(i),1)
        s w(i)=$li(r(i),1)
        w n(i)," ",s(w(i)),", Текущее состояние=",^CacheTempUser.jobs(n(i)),!

        ##; если подзадача выполнена удаляем ресурс и запоминаем результат
        if w(i)=1 {
          s m(i)=$li(r(i),2)
          d $system.Event.Delete(n(i))
          s c=c+1
        }
      }
    }
    
    ##; выдаём окончательный результат
    f i=1,2 w "Результат для [",n(i),"] = ",m(i),!
    
  }catch(ex){
    w "Ошибка",!,ex.DisplayString(),!
  }
  
  ##; прибираемся
  k ^CacheTempUser.jobs
  k ^tmp
}

ClassMethod SubTask(
  n,
  h)
{
  ##; выполняем суперсложный отчёт
  ##; временами обновляем текущий статус выполнения
  s r=""
  s key=$o(^tmp(n,""))
  while (key'="") {
    s ^CacheTempUser.jobs(n)=key
    s r=r_^tmp(n,key)
    s key=$o(^tmp(n,key))
    h h
  }

  ##; информируем процесс, ожидающий переданный ресурс, о завершении и передаём результат
  d $system.Event.Signal(n,r)
}

}