Код класса с использованием %ResultSetInclude (%occStatus,%occConstant,%occErrors)
Class sqlru.test
{

///<example>
///; Пример вызова:
///do ##class(sqlru.test).SQLExport("C:\data.txt","select 'Bună ziua','Добрый день','Good day' union select 4,5,6",$char(9),"'")
///</example>
/// Экспорт данных запроса в текстовый файл.
///<br>Параметры:
///<br><var>FileName</var> - полный путь к файлу (на сервере!);
///<br><var>Query</var> - текст запроса;
///<br><var>Delimiter</var> - разделитель столбцов;
///<br><var>StringQuote</var> - строковая кавычка;
ClassMethod SQLExport(
  FileName As %String,
  Query As %String,
  Delimiter As %Char,
  StringQuote As %Char) As %Status
{
  #dim ex As %Exception.AbstractException

  set sc=$$$OK
  try{

    if FileName="" $$$ThrowStatus($$$ERROR($$$DirectoryNameRequired))
    if ##class(%File).CreateDirectoryChain(##class(%File).GetDirectory(FileName,$$$YES))'=$$$YES $$$ThrowStatus($$$ERROR($$$FileNameInvalid,FileName))

    set stream=##class(%Stream.TmpBinary).%New()

    set rs = ##class(%ResultSet).%New()
    $$$ThrowOnError(rs.Prepare(Query))
    $$$ThrowOnError(rs.Execute())
    set len = rs.GetColumnCount()
    set line = ""  for i=1:1:len set line = line_rs.GetColumnName(i)_$select(i'=len:Delimiter,1:"")
    do stream.Write(line)
    while rs.Next() {
      set line = $$$NL for i=1:1:len set line = line_StringQuote_rs.GetData(i)_StringQuote_$select(i'=len:Delimiter,1:"")
      do stream.Write(line)
    }

    set file = ##class(%FileCharacterStream).%New()
    set file.TranslateTable="Unicode" ;UTF8, CP1251, CP866 и др.
    set file.Filename=FileName
    do file.CopyFromAndSave(stream)

  }catch(ex){
    set sc=ex.AsStatus()
  }
  quit sc
}

Classmethod Test() [Internal]
{
  set sc=##class(sqlru.test).SQLExport("C:\data.txt","select 'Bună ziua','Добрый день','Good day' union select 4,5,6",$char(9),"'")
  write $select($$$ISOK(sc):"OK",1:$system.Status.GetErrorText(sc,"ru"))
}

}

Код класса с использованием %SQL.StatementInclude (%occStatus,%occConstant,%occErrors)
Class sqlru.test
{

///<example>
///; Пример вызова:
///do ##class(sqlru.test).SQLExport("C:\data.txt","select 'Bună ziua','Добрый день','Good day' union select 4,5,6",$char(9),"'")
///</example>
/// Экспорт данных запроса в текстовый файл.
///<br>Параметры:
///<br><var>FileName</var> - полный путь к файлу (на сервере!);
///<br><var>Query</var> - текст запроса;
///<br><var>Delimiter</var> - разделитель столбцов;
///<br><var>StringQuote</var> - строковая кавычка;
ClassMethod SQLExport(
  FileName As %String,
  Query As %String,
  Delimiter As %Char,
  StringQuote As %Char) As %Status
{
  #dim ex As %Exception.AbstractException

  set sc=$$$OK
  try{

    if FileName="" $$$ThrowStatus($$$ERROR($$$DirectoryNameRequired))
    if ##class(%File).CreateDirectoryChain(##class(%File).GetDirectory(FileName,$$$YES))'=$$$YES $$$ThrowStatus($$$ERROR($$$FileNameInvalid,FileName))

    set stream=##class(%Stream.TmpBinary).%New()

    set st = ##class(%SQL.Statement).%New()
    $$$ThrowOnError(st.%Prepare(Query))
    set len = st.%Metadata.columnCount
    set rs=st.%Execute()
    set line = ""  for i=1:1:len set line = line_st.%Metadata.columns.GetAt(i).colName_$select(i'=len:Delimiter,1:"")
    do stream.Write(line)
    while rs.%Next() {
      set line = $$$NL for i=1:1:len set line = line_StringQuote_rs.%GetData(i)_StringQuote_$select(i'=len:Delimiter,1:"")
      do stream.Write(line)
    }

    set file = ##class(%FileCharacterStream).%New()
    set file.TranslateTable="Unicode" ;UTF8, CP1251, CP866 и др.
    set file.Filename=FileName
    do file.CopyFromAndSave(stream)

  }catch(ex){
    set sc=ex.AsStatus()
  }
  quit sc
}

Classmethod Test() [Internal]
{
  set sc=##class(sqlru.test).SQLExport("C:\data.txt","select 'Bună ziua','Добрый день','Good day' union select 4,5,6",$char(9),"'")
  write $select($$$ISOK(sc):"OK",1:$system.Status.GetErrorText(sc,"ru"))
}

}