pGrid.%ForceClientRender()

ClassMethod %DeserializePage(pHeader As %String, pBody As %String, Output pObjects) As %Status
{
	Set $ZT = "Trap"
	Set tSC = $$$OK

	Do {
		New %compositeList
	
		#; this should not happen
		If ((pHeader = "")||(pBody="")) Quit

		If ($IsObject(pHeader)) {
			#; header is a stream, not currently supported
			Set tSC = $$$ERROR($$$GeneralError,"Serial State Header is too large")
			Quit
		}
		
		#; first process header
		#; first record is list of class names
		Set tClassList = $P(pHeader,$C( 4 ), 1 )
		For c =  1 : 1 :$L(tClassList,$C( 1 )) {
			#; class # to class name
			Set tClasses(c) = $P(tClassList,$C( 1 ),c)
		}

		#; now walk down list of objects in header
		#; instantiate, and add to local, indexed list
		For o =  2 : 1 :$L(pHeader,$C( 4 )) {
			Set tObjInst = $P(pHeader,$C( 4 ),o)

			#; first  2  pieces are class # and obj index
			Set tClassNo = $P(tObjInst,$C( 1 ), 1 )
			Set tIndex = $P(tObjInst,$C( 1 ), 2 )

			#; dereference class #
			Set tClass = tClasses(tClassNo)

			Set pObjects(tIndex) = $zobjclassmethod(tClass,"%New")
			If (tIndex =  1 ) {
				#; this must be the page
				Set %page = pObjects(tIndex)
			}
		}

		#; now walk down body and apply property values
		#; test if body is provided as a stream or string
#ifdef MaxLocalLength
		Set CHUNK =  4000 
		Set MAXSTRING = $$$MaxLocalLength -  5000 
#else
		Set CHUNK =  4000 
		Set MAXSTRING =  26000 
#endif

		If ($IsObject(pBody)) {
			#; process stream in chunks
			Set tExtra = ""
			While (pBody.AtEnd =  0 ) {
				If ($L(tExtra) < MAXSTRING) {
					Set tChunk = tExtra _ pBody.Read(CHUNK)
				}
				Else {
					#; node too big
					Set tSC = $$$ERROR($$$GeneralError,"Node in Serial State is too large")
					Quit
				}
				#; process chunk
				Set p =  1 
				While (p >  0 ) {
					#; get next item
					Set next = $F(tChunk,$C( 4 ),p),tObjState = $S(next> 0 :$E(tChunk,p,next- 2 ), 1 :$E(tChunk,p,*))
					#; test for end of chunk v. end of stream
					If ((next= 0 )&&('pBody.AtEnd)) {
						Set tExtra = tObjState
						Quit
					}
					#; pull index out of 2nd piece and look up oref
					Set tObj = pObjects($P(tObjState,$C(1),2))
					Set tSC = tObj.%ZENDeserialize(tObjState,.pObjects)
					If $$$ISERR(tSC) Quit
					Set p = next
					Set tExtra = ""
				}
			}
		}
		Else {
			#; process string
			Set p = 1
			While (p > 0) {
				#; get next item
				Set next = $F(pBody,$C(4),p), tObjState = $S(next>0:$E(pBody,p,next-2),1:$E(pBody,p,*))
				#; pull index out of 2nd piece and look up oref
				Set tObj = pObjects($P(tObjState,$C(1),2))
				Set tSC = tObj.%ZENDeserialize(tObjState,.pObjects)
				If $$$ISERR(tSC) Quit
				Set p = next
			}
		}
		If $$$ISERR(tSC) Quit

		#; if %compositeList is defined, then we have deserialized
		#; a composite *before* deserializing the page
		If $D(%compositeList)&&$IsObject(%page) {
			Merge %page.%CompositeList = %compositeList
		}
	} While (0)
Done
	Quit tSC
Trap
	Set $ZT=""
	$$$ZENLOGERROR($ZE)
	&js<alert('Error deserializing page: #($ZCVT($ZE,"O","JS"))#\nProperty: #($G(tProp))#\nValue: #($G(tValue))#');>
	Goto Done
}

#Define MaxLocalLength  50000 

#Define MaxLocalLength  50000 

#Define MaxLocalLength  50000