;Set test string
  set zt="~"
  set N=10000
  set string=""
  for i=1:1:N-1 {
    set:i'=5000 string=string_"1~"
    set:i=5000 string=string_"A~"
  }
  set string=string_"B"
  
  ; Test ListFromString (A CLOSE #2 IN SPEED)
  k arr,list
  set t=$zhorolog
  set list=$listfromstring(string,zt)
  set ptr=0
  for i=1:1 {
    quit:'$listnext(list,ptr,value)
    s arr(i)=value
  }
  
  set t1=$zhorolog-t
  write "(t1) Time using $listnext = ",?25,t1," c.",!
  
  ; Test ListFromString - Get specific element
  k arr,value,list
  set t=$zhorolog
  set list=$listfromstring(string,zt)
  set ptr=0
  for i=1:1:5000 {
    quit:'$listnext(list,ptr,value)
  }
  write "A=",value
  k arr
  set t11=$zhorolog-t
  write "(t1.1) Time using $listnext element #5000 = ",?25,t11," c.",!
  write !
    
  ; Test List Get (ONLY SLIGHTLY FASTER THAN $PIECE)
  k arr,list
  set t=$zhorolog
  set list=$listfromstring(string,zt)
  set len=$LL(list)
  for i=1:1:len {
    set value=$LG(list,i)
    set arr(i)=value
  }
  set t2=$zhorolog-t
  write "(t2) Time using $listget = ",?25,t2," c.",!
  
  ; Test List Get for specific element
  k arr,value
  set t=$zhorolog
  set list=$listfromstring(string,zt)
  set value=$LG(list,5000)
  write "A=",value
  set t21=$zhorolog-t
  write "(t2.1) Time using $listget element #5000 = ",?25,t21," c.",!
  write !
  
  ; Test $Piece  (SLOWEST OPTION)
  k arr
  set t=$zhorolog
  set l=$l(string,zt)
  for i=1:1:l {
    set value=$p(string,"~",i)
    set arr(i)=value
  }
  set t3=$zhorolog-t
  write "(t3) Time using $p = ",?25,t3," c.",!
  ;write "t3/t1 = ",?25,t3/t1,"  -  [",t3/t1*100,"%]",!
  
  
  ; Test $Piece For specific element  (FASTEST BY FAR!)
  k arr,value
  set t=$zhorolog
  set value=$p(string,zt,5000)
  write "A=",value
  set t31=$zhorolog-t
  write "(t3.1) Time using $p for specific element #5000 = ",?25,t31," c.",!
  ;write "t31/t11 = ",?25,t31/t11,"  -  [",t31/t11*100,"%]",!
  write !
  
  ; Test $Find-$Extract (FASTEST!!!)
  k arr
  set t=$zhorolog
  set p1=1       ; starting pos
  set string=string_"~"    ; add delimiter to extract the last piece
  for i=1:1 {
    set p2=$f(string,"~",p1) q:p2=0
    set value=$e(string,p1,p2-2)
    set arr(i)=value
    set p1=p2
  }
  set t5=$zhorolog-t
  write "(t5) Time using $f/$e = ",?25,t5," c.",!
  ;write "t5/t1 = ",?25,t5/t1,"  -  [",t5/t1*100,"%]",!
  
  
  ; Test $Find-$Extract for specific element
  k arr,value
  set t=$zhorolog
  set p1=1       ; starting pos
  set string=string_"~"    ; add delimiter to extract the last piece
  for i=1:1 {
    set p2=$f(string,"~",p1) q:p2=0
    i i=5000 s value=$e(string,p1,p2-2) q
    set p1=p2
  }
  write "A=",value
  set t51=$zhorolog-t
  write "(t5.1) Time using $f/$e to get element #5000 = ",?25,t51," c.",!
  ;write "t5.1/t1 = ",?25,t51/t1,"  -  [",t51/t1*100,"%]",!
  write !
  quit