Private Sub FillFormF( _
        ByVal lngURL As Long, _
        ByVal lngSet As Long _
        )
    Dim IE As WebBrowser
    Dim objCollection As Object
    Dim rstFD As DAO.Recordset
    Dim rstFT As DAO.Recordset
    Dim strSQL As String
    Dim strFld As String
    'Dim col As Collection
    
    Set IE = Me.wb1.Object
    
    Application.SysCmd acSysCmdSetStatus, "Search form submission. Please wait..."
    
    Do While IE.Busy
        ' делаем небольшую задержку
        'Application.Wait DateAdd("s", 1, Now)
        Call Stoper(#12:00:01 AM#)
    Loop
    
    strSQL = ("SELECT tblSiteFieldType.StFTId, tblSiteFieldType.StFTName " _
            & "FROM (tblSiteFieldType INNER JOIN tblSiteField " _
                    & "ON tblSiteFieldType.StFTId = tblSiteField.StFldType) " _
                    & "INNER JOIN tblSiteFieldSet ON tblSiteField.StFldId = tblSiteFieldSet.SFSField " _
            & "WHERE (((tblSiteField.StFldUrl) = " & lngURL & ") " _
                & "AND ((tblSiteFieldSet.SFSSet)=" & lngSet & ")) " _
            & "GROUP BY tblSiteFieldType.StFTId, tblSiteFieldType.StFTName;")
    
    ' получаем набор типов полей
    Set rstFT = CurrentDb.OpenRecordset(strSQL)
    
    If rstFT.RecordCount > 0 Then rstFT.MoveFirst
    
    Do While Not rstFT.EOF
        
        Set objCollection = IE.Document.getElementsByTagName(rstFT!StFTName)
        
        strSQL = ("SELECT tblSiteField.StFldName, tblSiteField.StFldData " _
                & "FROM tblSiteField INNER JOIN tblSiteFieldSet ON tblSiteField.StFldId = tblSiteFieldSet.SFSField " _
                & "WHERE (((tblSiteField.StFldUrl)=" & lngURL & ") " _
                    & "AND ((tblSiteField.StFldType)=" & rstFT!StFTId & ")) " _
                    & "AND ((tblSiteFieldSet.SFSSet)=" & lngSet & ");")
        
        ' получаем набор полей и подставляемых в них данных
        Set rstFD = CurrentDb.OpenRecordset(strSQL)
        
        If rstFD.RecordCount > 0 Then rstFD.MoveFirst
        
        Do While Not rstFD.EOF
            strFld = rstFD!StFldName
            
            For i = 0 To objCollection.Length - 1
                'Debug.Print objCollection(i).Name
                If strFld = objCollection(i).Name Then
                    'Debug.Print objCollection(i).Name
                    objCollection(i).Value = rstFD!StFldData
                    
                    ' для корректной работы скрипта не выходим из цикла,
                    ' т.к. встречаются страницы с дублированными полями
                    'Exit For
                End If
            Next i
            
            rstFD.MoveNext
        Loop
        rstFD.Close
        
        rstFT.MoveNext
    Loop
    rstFT.Close
    
    Set objCollection = Nothing
    Set rstFD = Nothing
    Set rstFT = Nothing
    Set IE = Nothing
    
    Application.SysCmd acSysCmdSetStatus, "Поля заполнены. "
    
    MsgBox "Поля заполнены. ", vbInformation, Me.Caption
    
    Application.SysCmd acSysCmdSetStatus, " "
End Sub