function TdmlC.DataSetBy1CQuery(AText: string; Params: Variant): TClientDataSet;
var
  lCQuery, lCQueryResult, lCColumns, lCColumn :Variant;
  lCResultSelection :Variant;
  lCColTypes, lCDataType :Variant;
  StrDataType :string;
  i :Integer;
  FieldIsLink: array of Boolean;
begin
  Result := nil;

  if VarIsEmpty(lCDb) then // = Unassigned
    ConnectTo1C;

  lCQuery := lCDb.NewObject('Запрос');
  try
    lCQuery.Текст := AText;

    if (not VarIsNull(Params)) then
    begin
      for i := VarArrayLowBound(Params, 1) to VarArrayHighBound(Params, 1) do
      begin
        lCQuery.УстановитьПараметр(
          Params[i][0],
          lCDb.ЗначениеИзСтрокиВнутр(Params[i][1])
        );
      end;
    end;

    lCQueryResult := lCQuery.Выполнить();

    Result := TClientDataSet.Create(self);
    Result.FieldDefs.Clear;

    lCColumns := lCQueryResult.Колонки;
    if lCColumns.Количество > 0 then
    begin
      i := lCColumns.Количество;
      SetLength(FieldIsLink, i);

      for i := 0 to lCColumns.Количество - 1 do
      begin
        lCColumn := lCColumns.Получить(i);
        with Result.FieldDefs.AddFieldDef do
        begin

          Name := lCColumn.Имя;

          FieldIsLink[i] := False;

          lCColTypes := lCColumn.ТипЗначения.Типы();
          if lCColTypes.Count() <> 0 then
          begin
              lCDataType := lCColTypes.Get(0);
              if not VarIsNull(lCDataType) then
              begin
                strDataType := lCDb.String(lCDataType);

                if strDataType = 'Булево' then
                  DataType := ftBoolean
                else if strDataType = 'Дата' then
                  DataType := ftDateTime
                else if strDataType = 'Число' then
                  DataType := ftFloat
                else if strDataType = 'Строка' then
                begin
                  DataType := ftString;
                  Size := 256; //Size := Column.Ширина; ????
                end
                else
                begin
                  DataType := ftString;
                  FieldIsLink[i] := True;
                  Size := 256; //ссылка
                end;

              end;
          end;

        end; //adddef

      end; //for

    end; //if count > 0

    Result.CreateDataSet;
    lCResultSelection := lCQueryResult.Выбрать();
    while lCResultSelection.Next do
    begin
      Result.Append;
      for i := 0 to Result.FieldCount - 1 do
        if FieldIsLink[i] then
          Result.Fields[i].Value :=
            lCDb.ЗначениеВСтрокуВнутр(lCResultSelection.Получить(i))
        else
          Result.Fields[i].Value := lCResultSelection.Получить(i);
      Result.Post;
    end;

    Result.First;

  finally
    lCQuery := Unassigned;
    lCQueryResult := Unassigned;
    lCColumns := Unassigned;
    lCColumn := Unassigned;
    lCColTypes := Unassigned;
    lCDataType := Unassigned;
    lCResultSelection := Unassigned;
  end;

end;

РезультатЗапроса = Запрос.Выполнить();
ДлинаПоля = РезультатЗапроса.Колонки[0].Ширина; //равно 30-ти, а должно быть больше