Всем, здравствуйте!

Подскажите, каким образом можно сделать следующее:
Имею форму. На форме кнопка и несколько полей. Жму на кнопку - вызывается формасписка регистра сведений (в качестве формы выбора). Выбираю нужную мне запись регистра сведений. Окно списка закрывается. Некоторые значения данных из выбранной записи должны быть занесены в поля на форме.

Естественно, много гуглил. Взял за основу вариант http://pro1c.org.ua/index.php?showtopic=276.
Но в 8.2 мне его никак "не уложить".

Почти все работает, кроме того, что никак не установить владельца открываемой формысписка регистра сведений. А раз нет владельца, то выбранные в формесписка данные возвращаются "в никуда".

Дополню свой вопрос. Есть код в модуле формы, из которой вызывается формасписка регистра сведений.

&НаСервере
Процедура ПриложениеНачалоВыбораНаСервере()
// Создадим ключ, идентифицирующий строку в списке регистра
ДанныеКлюча = Новый Структура("Период, Приложение", ЭтаФорма.Элементы.ПриложениеПериод, ЭтаФорма.Элементы.Приложение);
Ключ = РегистрыСведений["Приложения"].СоздатьКлючЗаписи(ДанныеКлюча);

// Создадим форму регистра и откроем ее
ФормаРС = РегистрыСведений["Приложения"].ПолучитьФорму("ФормаВыбора");
ФормаРС.Параметры.КлючНазначенияИспользования=Ключ;
ФормаРС.Параметры.РежимВыбора = Истина;
ФормаРС.ВладелецФормы = ЭтаФорма;
ФормаРС.ОткрытьМодально();
КонецПроцедуры

&НаКлиенте
Процедура ПриложениеНачалоВыбора(Элемент, ДанныеВыбора, СтандартнаяОбработка)
СтандартнаяОбработка = Ложь;
ПриложениеНачалоВыбораНаСервере();
КонецПроцедуры

&НаКлиенте
Процедура ПриложениеОбработкаВыбора(Элемент, ВыбранноеЗначение, СтандартнаяОбработка)
// Обработаем значение выбора
СтандартнаяОбработка = Ложь;
ПриложениеПериод = ВыбранноеЗначение.Период;
Приложение = ВыбранноеЗначение.Приложение;
КонецПроцедуры

Также есть код в формесписка для обработки выбора записи:

// Форма списка регистра сведений
&НаКлиенте
Процедура СписокВыбор(Элемент, ВыбраннаяСтрока, Поле, СтандартнаяОбработка)
ОповеститьОВыборе(ВыбраннаяСтрока);
СтандартнаяОбработка = Ложь;
КонецПроцедуры

Дык вот ошибка в строке:
ФормаРС.ВладелецФормы = ЭтаФорма; .
Пишет - несоответствие типов.
Пробовал писать сюда:
ФормаРС = РегистрыСведений["Приложения"].ПолучитьФорму("ФормаВыбора", ЭтаФорма);
Пропускает "мимо ушей". Значение ВладелецФормы остается "Неопределено".

Может кто незамыленным глазом что-нибуть подскажет? ;)

Господин ПЖкод странный... пытаться создать форму на сервере через ПолучитьФорму, который доступен только на толстом клиенте...

Готов выслушать конструктивную критику ;)
У меня такая бурная фантазия, потому что нет нормальных примеров. Вот и изобретаю...

На клиенте это не работает =)
ФормаРС = РегистрыСведений["Приложения"].ПолучитьФорму("ФормаВыбора");

Господин ПЖKuzEvНа клиенте это не работает =)
ФормаРС = РегистрыСведений["Приложения"].ПолучитьФорму("ФормаВыбора");

клиент то тонкий вероятно... будем СП читать про ОткрытьФорму() или дальше мудрить?

Клиент толстый, гад =)
Предлагаете заюзать ОткрытьФорму() на клиенте?

Господин ПЖФормаРС = РегистрыСведений["Приложения"].ПолучитьФорму("ФормаВыбора") не работает

А что говорит?

{РегистрСведений.ИБПриложения.Форма.ФормаЗаписи.Форма(86,15)}: Переменная не определена (РегистрыСведений)
ФормаРС = <<?>>РегистрыСведений["Приложения"].ПолучитьФорму("ФормаВыбора"); (Проверка: Тонкий клиент)

Хм, клиент тонкий, гад =)

После "пинка" Господина ПЖ исправил для Толстого клиента так:

&НаКлиенте
Процедура ОбработкаВыбора(ВыбранноеЗначение, ИсточникВыбора)
// Обработаем значение выбора
Запись.ПриложениеПериод = ВыбранноеЗначение.Период;
Запись.Приложение = ВыбранноеЗначение.Приложение;
КонецПроцедуры

&НаКлиенте
Процедура ПриложениеНачалоВыбора(Элемент, ДанныеВыбора, СтандартнаяОбработка)
СтандартнаяОбработка = Ложь;
ДанныеКлюча = Новый Структура("Период, Приложение", ЭтаФорма.Элементы.ПриложениеПериод, ЭтаФорма.Элементы.Приложение);
Ключ = РегистрыСведений["Приложения"].СоздатьКлючЗаписи(ДанныеКлюча);

// Создадим форму регистра и откроем ее
//ФормаРС = РегистрыСведений["Приложения"].ПолучитьФормуСписка("ФормаВыбора", ЭтаФорма.Элементы.Приложение);
ФормаРС = РегистрыСведений["Приложения"].ПолучитьФорму("ФормаВыбора");
ФормаРС.Параметры.КлючНазначенияИспользования=Ключ;
ФормаРС.Параметры.РежимВыбора = Истина;
ФормаРС.ВладелецФормы = ЭтаФорма;
ФормаРС.ОткрытьМодально();
КонецПроцедуры

Буду думать теперь для Тонкого клиента.

Слушаюсь, мой Господин =)

При использовании ОткрытьФорму(<ИмяФормы>, <Параметры>, <Владелец>, <Уникальность>, <Окно>) нужно задействовать <Параметры>.

Значение ключа можно "подготовить" на клиенте?
Если мне нужно отобрать записи регистра сведений за определенный период?

KuzEvСлушаюсь, мой Господин =)

При использовании ОткрытьФорму(<ИмяФормы>, <Параметры>, <Владелец>, <Уникальность>, <Окно>) нужно задействовать <Параметры>.

Значение ключа можно "подготовить" на клиенте?
Если мне нужно отобрать записи регистра сведений за определенный период?

Вот как я пока сделал.

У формысписка (форме для выбора) сделал две процедуры:

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
СтандартнаяОбработка = Ложь;
ЭтаФорма.Список.ПроизвольныйЗапрос=Истина;
ЭтаФорма.Список.ТекстЗапроса="
|ВЫБРАТЬ
| РегистрСведенийПриложения.Период,
| РегистрСведенийПриложения.Приложение,
| РегистрСведенийПриложения.Версия,
| РегистрСведенийПриложения.ДатаВыхода,
| РегистрСведенийПриложения.Сервер,
| РегистрСведенийПриложения.Каталог,
| РегистрСведенийПриложения.Примечание
| ИЗ
|РегистрСведений.Приложения КАК РегистрСведенийПриложения
| ГДЕ
|РегистрСведенийПриложения.Период <= &АктуальнаяДата
|";
ЭтаФорма.Список.Параметры.УстановитьЗначениеПараметра("АктуальнаяДата", Параметры.АктуальнаяДата);
КонецПроцедуры

&НаКлиенте
Процедура СписокВыбор(Элемент, ВыбраннаяСтрока, Поле, СтандартнаяОбработка)
СтандартнаяОбработка = Ложь;
ОповеститьОВыборе(ВыбраннаяСтрока);
КонецПроцедуры

А в форме, из которой вызываю формусписка так:
// Приложение - элемент формы

&НаКлиенте
Процедура ПриложениеНачалоВыбора(Элемент, ДанныеВыбора, СтандартнаяОбработка)
СтандартнаяОбработка = Ложь;
ПараметрыВыбора = Новый Структура;
ПараметрыВыбора.Вставить("РежимВыбора", Истина);
ПараметрыВыбора.Вставить("ЗакрыватьПриВыборе", Истина);
ПараметрыВыбора.Вставить("ТолькоПросмотр", Истина);
ПараметрыВыбора.Вставить("АктуальнаяДата", Запись.Период);
ПараметрыВыбора.Вставить("Приложение", Запись.Приложение);
ПараметрыВыбора.Вставить("ПриложениеПериод", Запись.ПриложениеПериод);
ОткрытьФорму("РегистрСведений.Приложения.Форма.ФормаДляВыбора",ПараметрыВыбора,ЭтаФорма.Элементы.Приложение);
КонецПроцедуры

&НаКлиенте
Процедура ПриложениеОбработкаВыбора(Элемент, ВыбранноеЗначение, СтандартнаяОбработка)
// Обработаем значение выбора
СтандартнаяОбработка = Ложь;
Запись.ПриложениеПериод = ВыбранноеЗначение.Период;
Запись.Приложение = ВыбранноеЗначение.Приложение;
КонецПроцедуры