Sub Fix(oFiles, sXQuery)
  Dim sFile, oXMLFile, oXMLNodes, oXMLNode, oXMLAttribs, oXMLAttrib
  If Len(sXQuery) > 0 Then
    Set oXMLFile = CreateObject("MSXML2.DOMDocument.6.0")
    For Each sFile in oFiles.Keys
      WScript.Echo "Loading XML file " & sFile
      If oXMLFile.Load(sFile) Then
        Set oXMLNodes = oXMLFile.selectNodes(sXQuery)
        If oXMlNodes.Length > 0 then
          WScript.Echo "Found " & oXMlNodes.Length & " items"
          For Each oXMLNode In oXMLNodes
            WScript.Echo oXMLNode.nodeName
            Set oXMLAttribs = oXMLNode.attributes
            If oXMLAttribs.length >0 then
              For Each oXMLAttrib in oXMLAttribs
                WScript.Echo oXMLAttrib.nodeName & " " & oXMLAttrib.nodeValue
                If oXMLAttrib.nodeName = "Value" Then
                  oXMLAttrib.nodeValue = "Yes"
                  WScript.Echo "Value changed to " & oXMLAttrib.nodeValue
                End IF
                If oXMLAttrib.nodeName = "ValueLocalizeID" Then
                  oXMLAttrib.nodeValue = "SYSRES_COMMON.YES_CONST"
                  WScript.Echo "Value changed to " & oXMLAttrib.nodeValue
                End IF
                WScript.Echo oXMLAttrib.nodeName & " " & oXMLAttrib.nodeValue
              Next
            End If
            Set oXMLAttribs = Nothing
          Next
          oXMLFile.Save(sFile)
        Else
          WScript.Echo "Nothing found!"
        End If
        Set oXMLNodes = Nothing
      End If
    Next
    Set oXMLFile = Nothing
  End If
End Sub