Option Explicit


' Константа для указания что мы хотим получить/установить адрес оконной функции
Private Const GWL_WNDPROC = - 4 
' Константа идентифицирующая сообщение
Private Const WM_CHAR& = &H102

Private lpPrevWndProc As Long
Private gHW As Long

Public Declare Function DefWindowProc Lib "user32" Alias _
   "DefWindowProcA" (ByVal hwnd As Long, ByVal wMsg As Long, _
    ByVal wParam As Long, ByVal lParam As Long) As Long
Public Declare Function CallWindowProc Lib "user32" Alias _
   "CallWindowProcA" (ByVal lpPrevWndFunc As Long, _
    ByVal hwnd As Long, ByVal Msg As Long, _
    ByVal wParam As Long, ByVal lParam As Long) As Long
Public Declare Function SetWindowLong Lib "user32" Alias _
   "SetWindowLongA" (ByVal hwnd As Long, _
    ByVal nIndex As Long, ByVal dwNewLong As Long) As Long

Public Sub Hook(gHW_ As Long)
    'Start subclassing.
' Сохраняем переданный hWnd для последующего возврата стандартной оконной функции
    gHW = gHW_
' Подменяем стандартную оконную функцию на пользовательскую
' Адрес старой функции сохраняется в переменной lpPrevWndProc и нужен
' для вызова стандартной функции, а так-же для возврата на место, когда все закончим :)
    lpPrevWndProc = SetWindowLong(gHW, GWL_WNDPROC, _
       AddressOf WindowProc)
End Sub

Public Sub Unhook()
    Dim temp As Long

    'Cease subclassing.
' Снимаем свой сабклассинг - возвращаем стандартную оконную функцию.
    temp = SetWindowLong(gHW, GWL_WNDPROC, lpPrevWndProc)
End Sub

Function WindowProc(ByVal hw As Long, ByVal uMsg As Long, _
   ByVal wParam As Long, ByVal lParam As Long) As Long
  ' Пользовательская оконная функция. Имя может быть произвольным, имена параметров тоже.
' Но! к таким имена все привыкли, поэтому рекомендую не менять имена параметров :)

' здесь можно написать Select Case - если много сообщений нужно обрабатывать
' или обойтись простым If
    If uMsg = WM_CHAR Then
        If wParam = Asc(".") Then
            wParam = Asc(",")
        End If
    End If
' все сообщения, которые нас НЕ интересуют должны отправлятся на обработку в стандартную оконную функцию:
        WindowProc = CallWindowProc(lpPrevWndProc, hw, uMsg, _
           wParam, lParam)
End Function

Option Explicit


Private Sub Form_Load()
' Делаем подмену оконной функции
Hook Text1.hwnd
End Sub

Private Sub Form_Unload(Cancel As Integer)
' Возвращаем стандартную оконную функцию
Unhook
End Sub