Const H = 4, W = 4                  ' размер поля - 4х4
Const CH = 50, CW = 50              ' размер клетки - 50x50

Dim stp(1 To W, 1 To H) As Integer  ' правильное расположение
                                    ' фишек
Dim pole(1 To W, 1 To H) As Integer ' игровое поле
Dim ex As Integer, ey As Integer    ' координаты пустой клетки

' новая игра
Sub newGame()

   For i = 1 To W Step 1
      For j = 1 To H Step 1
         ' правильное расположение фишек
         stp(i, j) = (i - 1) * W + j
         pole(i, j) = stp(i, j)
      Next j
   Next i

   stp(W, H) = 0
   
   ' перемешивание фишек и вывод поля
   Call mixer
   Call showPole
End Sub

' вывод игрового поля
Sub showPole()

   Dim i As Integer, j As Integer
   Dim X As Integer, Y As Integer   ' x,y - координаты вывода
                                    ' текста в клетке
   
   ' очистка поля от предыдущего хода
   Form1.Cls
   
   ' сетка: вертикальные линии
   For i = 1 To (W - 1)
      Line (i * CW, 0)-(i * CW, CH * H)
   Next i
    
   ' сетка: горизонтальные линии
   For i = 1 To (H - 1)
      Line (0, i * CH)-(CW * W, i * CH)
   Next i
      
   ' содержимое клеток (цифры фишек)
   For i = 1 To H
      Y = (i - 1) * CH + 18
      For j = 1 To W
            X = (j - 1) * CW + 18
            Select Case pole(i, j)
               Case 0:
               Case 1 To 9:
                  CurrentX = X
                  CurrentY = Y
                  Print " " + Format(pole(i, j))
               Case 10 To 15:
                  CurrentX = X
                  CurrentY = Y
                  Print Format(pole(i, j))
            End Select
      Next j
   Next i

End Sub

' функция проверяет, расположены ли фишки в нужном порядке
Function Finish() As Boolean
   Dim row As Integer, col As Integer
   ' координаты фишки
   
   row = 1
   col = 1
   Finish = True    ' пусть фишки расположены в нужном порядке

   For i = 1 To (W * H - 1)
      If pole(row, col) <> i Then
         Finish = False
         Exit Function
      End If

      ' к следующей клетке
      If col < W Then
         col = col + 1
      Else
         col = 1
         row = row + 1
      End If
   Next i
   
End Function

' процедура '"перемешивает" фишки
Sub mixer()
   Dim x1 As Integer, y1 As Integer ' координаты пустой фишки
   Dim x2 As Integer, y2 As Integer ' координаты фишки,
                                    ' перемещаемой на место
                                    ' пустой
   Dim d As Integer                 ' направление перемещения,
                                    ' относительно пустой
                                    ' фишки
   x1 = W
   y1 = H
   
   For i = 1 To W * H * 10 Step 1
      Do
         x2 = x1
         y2 = y1
         d = Int((Rnd * W) + 1)     ' предполагается, что поле
                                    ' квадратное
         Select Case d
            Case 1: x2 = x2 + 1
            Case 2: x2 = x2 - 1
            Case 3: y2 = y2 + 1
            Case 4: y2 = y2 - 1
         End Select

      Loop Until (x2 >= 1) And (x2 <= W) And _
                 (y2 >= 1) And (y2 <= H)
    
      pole(y1, x1) = pole(y2, x2)
      pole(y2, x2) = 0

      x1 = x2
      y1 = y2
   Next i
   
   ' запоминание координаты пустой клетки
   ex = x1
   ey = y1
End Sub

' процедура "перемещает" фишку в соседнюю пустую клетку, если
' она есть, конечно
Sub fMove(cx As Integer, cy As Integer)
   ' cx, cy - клетка, в которой игрок сделал щелчок

   ' проверка возможности обмена
   If Not ((Abs(cx - ex) = 1) And (cy - ey = 0) Or _
           (Abs(cy - ey) = 1) And (cx - ex = 0)) Then Exit Sub

   ' обмен: перемещение фишки из (x, y) в (ex, ey)
   pole(ey, ex) = pole(cy, cx)
   pole(cy, cx) = 0
   ex = cx
   ey = cy
    
   ' вывод поля
   Call showPole
   
   If Finish = True Then
      y_n = MsgBox("Цель достигнута!" + Chr(13) + _
                   "Еше раз?", vbYesNo, "Игра 15")
      If y_n = vbYes Then Call newGame      ' новая игра
      If y_n = vbNo Then Unload Form1       ' завершение
                                            ' работы программы
   End If

End Sub

' инициализация формы
Private Sub Form_Initialize()
   Form1.Width = (Form1.Width - Form1.ScaleWidth) + _
                 (CW * W) * Screen.TwipsPerPixelX
   Form1.Height = (Form1.Height - Form1.ScaleHeight) + _
                  (CH * H) * Screen.TwipsPerPixelY
   Form1.Font.Size = 10
   Form1.ScaleMode = 3
   
   Randomize
   Call newGame
End Sub

' щелчок мышки на форме
Private Sub Form_MouseDown(Button As Integer, _
   Shift As Integer, X As Single, Y As Single)
   ' X, Y - координаты щелчка

   Dim cx As Integer, cy As Integer     ' координаты клетки

   ' преобразуем щелчок в координаты клетки
   cx = Int(X / CW) + 1
   cy = Int(Y / CH) + 1

   Call fMove(cx, cy)
End Sub

' обработка события Paint
Private Sub Form_Paint()
   Call showPole
End Sub