procedure BLOBToOleContainer(const Stream: TStream; OleContainer : TOleContainer);
  type
    TStreamHeader = record
      case Integer of
        0: ( // New
          Signature: Integer;
          DrawAspect: Integer;
          DataSize: Integer);
        1: ( // Old
          PartRect: TSmallRect);
    end;

  const
    StreamSignature = $434F4442;
    DVASPECT_CONTENT   = 1;
    DVASPECT_ICON      = 4;

  var
    Header : TStreamHeader;
    TempStream : TMemoryStream;
    R : TRect;
begin
  if OleContainer.OldStreamFormat then
  begin
    R := OleContainer.BoundsRect;
    Header.PartRect.Left := R.Left;
    Header.PartRect.Top := R.Top;
    Header.PartRect.Right := R.Right;
    Header.PartRect.Bottom := R.Bottom;
  end else
  begin
    Header.Signature := StreamSignature;
    if OleContainer.Iconic
      then Header.DrawAspect := DVASPECT_ICON
      else Header.DrawAspect := DVASPECT_CONTENT;
  end;

  TempStream := TMemoryStream.Create;
  try
    Header.DataSize := Stream.Size;
    TempStream.Write(Header, SizeOf(Header));
    Stream.Position := 0;
    TempStream.CopyFrom(Stream, Header.DataSize);
    TempStream.Position := 0;
    OleContainer.LoadFromStream(TempStream);
  finally
    TempStream.Free;
  end;
end;

procedure BLOBToExcel(const Stream: TStream);
var
  DataHandle: HGLOBAL;
  Buffer: Pointer;
  FLockBytes: ILockBytes;
  FStorage: IStorage;
  FOleObject: IOleObject;
begin
  DataHandle := GlobalAlloc(GMEM_MOVEABLE, Stream.Size);
  if DataHandle = 0 then OutOfMemoryError;
  try
    Buffer := GlobalLock(DataHandle);
    try
      Stream.Read(Buffer^, Stream.Size);
    finally
      GlobalUnlock(DataHandle);
    end;
    CreateILockBytesOnHGlobal(DataHandle, True, FLockBytes);
    OleCheck(StgOpenStorageOnILockBytes(FLockBytes, nil, STGM_READWRITE or STGM_SHARE_EXCLUSIVE, nil, 0, FStorage));
    OleCheck(OleLoad(FStorage, IOleObject, nil, FOleObject));
    FOleObject.DoVerb(0, nil, nil, 0, 0, Rect(0, 0, 0, 0));

//    XLAPP := GetActiveOleObject('Excel.Application'); // коннектимся
//    или можно делать CreateOleObject, но раньше
//    или если нужно раннее связывание
//    XLApp := TExcelApplication.Create(Application);
//    XLApp.ConnectKind := ckRunningOrNew;
//    XLApp.Connect;
//    а дальше всё как обычно

  except
    if (DataHandle <> 0)
      then GlobalFree(DataHandle);
    if (FOleObject <> nil)
      then FOleObject.Close(OLECLOSE_NOSAVE);
    raise;
  end;
end;