Simulating MDI without MDI OverheadThe reason I bought Delphi in the first place was to make a Win95 version of my favorite file manager, XTree for Windows 2.0. I'd never programmed before and realized soon that such a project was beyond my abilities. Two years later I've tried again, and this time I got it done (
http://www.fyi.net/~abass/domino/free.htm if you're interested).
One of the things I needed to to do was to get a MDI setup that didn't show scrollbars in the parent window if a child was moved partially 'offscreen.' The nature of MDI won't allow that, however. I also wanted to have the child's title bar and min/max buttons appear in the client area of the parent when the child was maximized, instead of having the titlebar disappear and the buttons appended below the parent's buttons. Again, not allowed with MDI.
Then, while searching for something else, I stumbled across a great article and sample program that did it all. The author is Brendan Delumpa and he has a great site of Delphi tips at www.delumpa.com. Check it out. This particular article I didn't find at his site, however. It is instead at The Cobb Group's website (not reproduced here for fear of copyright problems :-)
http://www.cobb.com/ddj/9704/ddj9741.htm.
I recommend reading this article before you get going with the code below but I guess it isn't really necessary as the code does do all that you need and if you just use it as a base to build on, you'll get your desired results. Still, the article is a good read and details very well how Delumpa "Tricked Windows" into letting him do what he wanted.
The downside? Well, there's a little work involved, and you'll be responsible for all other MDI niceties such as the Window Menu. But it can be done and it results in a pretty slick interface (look to DTree above, seriously).
Below is the code for a 'parent' and 'child' form ala Brendan Delumpa. There are no controls on the child and only a "new child" button on the parent form so you can easily create them in Delphi and just drop this code into them. NOTE that this code will not get you everything you'll see in DTree; I put a whole lot of extra stuff in and around this base.
THE CHILD FORM:
{===========================================================
Copyright © 1997 Brendan V. Delumpa All Rights Reserved
Program : Child Form
Author : Brendan V. Delumpa
Description : This is a demonstration of creating a pseudo-MDIChild
form, without the MDI overhead or complexities.
Everything you can do with a top-level form can be
applied to this child form, which is actually not
possible with a MDI application because of the child
constraints.
One thing that you should note. I've brute forced
form activation here by sending WM_NCACTIVATE to
change the color of an "active" child form's caption
bar. This is Windows trickery at its best. In all
actuality, none of the "child" forms is active, nor
focused, even though they appear to be. Pretty neat, huh?
===========================================================}
unit ChildFor;
interface
uses
Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
ComCtrls, StdCtrls;
type
TChildFrm = class(TForm)
Label1: TLabel;
private
ChildHndl : THandle;
protected
procedure CreateParams(var Params : TCreateParams); override;
procedure WndProc(var Msg : TMessage); override;
procedure ActivateForm; virtual;
public
{ Public declarations }
end;
var
ChildFrm: TChildFrm;
implementation
uses Unit1;
{$R *.DFM}
{===========================================================
This procedure overrides the default CreateParams procedure to set
the form up as a Child window. This is done through the Style param.
Note that when you set a form to be a child, it cannot have WS_POPUP
as a style parameter as well, so it's AND'ed out. Setting WndParent
and Parent to Application.MainForm notifies Delphi and Windows
respectively, of the relationship. ===========================================================}
procedure TChildFrm.CreateParams(var Params : TCreateParams);
begin
inherited CreateParams(Params);
with Params do begin
{Set the child window's style - WS_CHILD is absolutely required
but you can optionally set other flags as well.}
Style := (Style OR WS_CHILD) AND (NOT WS_POPUP);
{The following should be added to the line above if you want to
make an expert form.
AND (NOT WS_CAPTION) AND (NOT WS_THICKFRAME);}
{Designate the child form's parent}
WndParent := Application.MainForm.Handle;
end;
Parent := Application.MainForm;
end;
{===========================================================
WndProc is a wrapper for a Windows WindowProc which is the message
dispatcher for all messages sent to a window. It's an ideal place to
trap and process several messages in one fell swoop.
This one little routine is responsible for making the form act like
a MDIChild form, by trapping WM_CREATE, WM_LBUTTONDOWN, and
WM_NCLBUTTONDOWN messages. What it does is it tricks Windows into
thinking that the form is a top-level window by sending a WM_ACTIVATE
message to. This essentially makes the form's caption turn to the
default Active form color. Then the call is made to ActivateForm
to make all the other "Child" windows of the same class inactive. ===========================================================}
procedure TChildFrm.WndProc(var Msg : TMessage);
begin
{Call the default Window procedure so all default
actions are taken on all messages}
inherited WndProc(Msg);
{If the following occur, take further action}
if (Msg.Msg = WM_CREATE) OR {window create}
(Msg.Msg = WM_LBUTTONDOWN) OR {left-click in client area}
(Msg.Msg = WM_RBUTTONDOWN) OR {right-click in client area}
(Msg.Msg = WM_NCLBUTTONDOWN) OR {left-click in non-client area}
(Msg.Msg = WM_NCRBUTTONDOWN) then{right-click in non-client area}
begin
{"Trick" Windows into thinking this is an active, top-level form.}
Perform(WM_NCACTIVATE, Ord(True), 0);
{Change all other forms of the same class to look inactive.}
ActivateForm;
end
end;
{===========================================================
ActivateForm is the workhorse for WndProc. I probably could have
embedded this code in WndProc itself, but thought the better of it
since I wanted WndProc to maintain its identity as a dispatcher.
This procedure first assigns an interface (therefore global) variable
the value of the current form's handle, then iterates through all the
forms on the screen using the Screen global variable Forms property.
If it finds a form of the same class as the current form, it checks
to see if its handle is equal to the value of the global variable. If
it's not, then WM_NCACTIVATE is sent with a wParam of false to make
the form "inactive." This is actually necessary because the dispatcher
sets the form to "active" and it will stay that way regardless of
focus. So I needed to find a way to "inactivate" the other forms of the
same class.
==========================================================}
procedure TChildFrm.ActivateForm;
var
I : Integer;
begin
inherited;
{Set the private ChildHndl variable to Self.Handle,
so we know which form is active}
ChildHndl := Self.Handle;
Self.BringToFront;
{I use the red code instead of Delumpa's blue code below.
My code deactivates ALL other forms except for the 'parent' form.}
for i := 0 to screen.formcount -1 do
if (screen.Forms[i].ClassName <> parentfor.ClassName)
then SendMessage(screen.Forms[i].Handle, WM_NCACTIVATE, Ord(False), 0);
with Screen do begin
{Go through all the forms on screen.}
for I := 0 to FormCount - 1 do
if (Forms[I].ClassName = Self.ClassName) then
if (Forms[I].Handle <> ChildHndl) then
{If a "Child" is of the same type, but not the current one,
as specified by ChildHndl then make it inactive}
SendMessage(Forms[I].Handle, WM_NCACTIVATE, Ord(False), 0);
end;
end;
end.
THE PARENT FORM:
unit Parentfor;
interface
uses
Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
StdCtrls;
type
TParentFrm = class(TForm)
Button1: TButton;
procedure Button1Click(Sender: TObject);
private
{ Private declarations }
public
{ Public declarations }
end;
var
ParentFrm: TParentFrm;
implementation
uses
ChildFor;
{$R *.DFM}
procedure TParentFrm.Button1Click(Sender: TObject);
var
frm : TChildFrm;
begin
frm := TChildFrm.Create(Application);
with frm do begin
Left := 50;
Top := 50;
Show;
end;
end;
end.
