alter session set plsql_debug = FALSE -- это главное
/
alter session set plsql_optimize_level = 2
/
alter session set plsql_code_type = native
/
set serveroutput on;

DECLARE
   outer_loop_count constant pls_integer := 100000; --00; -- уменьшим, чтобы не ждать слишком долго
   inner_loop_count constant pls_integer := 100;
   
   cn_sum constant Number := 1.015;
   cd_sum constant binary_double := 1.015d;
   cf_sum constant binary_float := 1.015f;
   
   s_number NUMBER;
   s_number2 NUMBER;
   -- 32-bit floating point number. This data type requires 4 bytes.
   s_binary_float BINARY_FLOAT;
   s_binary_float2 BINARY_FLOAT;
   -- 64-bit floating point number. This data type requires 8 bytes.
   s_binary_double  BINARY_DOUBLE;
   s_binary_double2 BINARY_DOUBLE;
   --
   t_start NUMBER;
   t_stop Number;
   
BEGIN
   dbms_output.put_line('Loop count = ' || outer_loop_count);
   -- NUMBER
   t_start := dbms_utility.get_cpu_time;
   s_number := 0.0;
   FOR n IN 1 .. outer_loop_count LOOP
     s_number2 := 1.0;
     For k in 1..inner_loop_count
     Loop
       s_number2 := s_number2 * cn_sum + Log(2,s_number2); 
     End Loop;    
     s_number := s_number + s_number2;
     s_number := s_number + log(2,s_number);
   END LOOP;

   t_stop := dbms_utility.get_cpu_time();
   dbms_output.put_line('NUMBER        exec time = '
      ||0.01*(t_stop-t_start)|| ' res='||s_number);
   -- 
   -- BINARY_FLOAT
   s_binary_float := 0.0f;
   t_start := dbms_utility.get_cpu_time;
   FOR n IN 1 .. outer_loop_count LOOP
     s_binary_float2 := 1.0f;
     For k in 1 .. inner_loop_count
     Loop
       s_binary_float2 := s_binary_float2 * cf_sum + log(2, s_binary_float2); 
     End Loop;         
      s_binary_float := s_binary_float + s_binary_float2; -- 1.0f;
      s_binary_float := s_binary_float + log(2,s_binary_float);        
   END LOOP;
   t_stop := dbms_utility.get_cpu_time();
   dbms_output.put_line('BINARY_FLOAT  exec time = '
      ||0.01*(t_stop-t_start)|| ' res='||s_binary_float);
   -- 
   -- BINARY_DOUBLE
   s_binary_double := 0.0d;
   t_start := dbms_utility.get_cpu_time;
   FOR n IN 1 .. outer_loop_count LOOP
     s_binary_double2 := 1.0d;
     For k in 1 .. inner_loop_count
     Loop
       s_binary_double2 := s_binary_double2 * cd_sum + log(2,s_binary_double2); 
     End Loop;         
      s_binary_double := s_binary_double + s_binary_double2; 
      s_binary_double := s_binary_double + log(2,s_binary_double);              
   END LOOP;
   t_stop := dbms_utility.get_cpu_time();
   dbms_output.put_line('BINARY_DOUBLE exec time = '
      ||0.01*(t_stop-t_start)|| ' res='||s_binary_double);

END;
/