*************************************************************
*формирование нового кода записи в указанном или в текущем alias
*************************************************************
*Параметры
*tcAlias - имя таблицы без расширения для которой следует сформировать новый ID
*************************************************************
*Возвращаемое значение
*В случае успешного формирования, возвращается сформированный ID
*В случае неудачи, возвращается значение NULL
*************************************************************
*Замечание
*Рекомендуется установить для ключевых полей таблиц признак NOT NULL, тогда
*в случае неудачного формирования ID возникнет сообщение об ошибке при попытке
*записать это ID в ключевое поле таблицы
*************************************************************
FUNCTION NewID(tcAlias)
  LOCAL lcAlias
  IF TYPE( "tcAlias" )<> "C"  OR EMPTY(m.tcAlias)=.T.
    lcAlias = UPPER(ALIAS())
  ELSE
    lcAlias = UPPER(AllTrim(m.tcAlias))
  ENDIF

  LOCAL lnNewID
  lnNewID=NULL
  
  * Некоторые обязательные предварительные настройки среды
  LOCAL lcReprocess, lnArea, lcError, llIsUsedTabLists
  lnArea = SELECT()
  lcReprocess = SET('REPROCESS')
  SET REPROCESS TO  3 
  lcError=ON( "ERROR" )
  ON ERROR *	&& подавляю выдачу сообщений об ошибках
  llIsUsedTabLists=USED( "TabLists" )
  
  * Если служебная таблица не открыта, то открываю ее
  IF m.llIsUsedTabLists=.F.
    USE Leasing!TabLists IN  0 
  ENDIF
  
  * Дополняю имя таблицы пробелами справа до длины поля TabLists.TableName
  * чтобы исключить поиск по первым символам
  IF USED( "TabLists" )=.T. AND LEN(m.tcAlias)<LEN(TabLists.TableName)
  	m.tcAlias=PADR(m.tcAlias,LEN(TabLists.TableName))
  ENDIF

  * Вариант, когда указанный алиас не найден в служебной таблице
  * рассматривается как ошибка и новый номер ID не присваивается
  * Проверка на блокировку и собственно блокировка найденной записи 
  * предотвращают ряд специфических ошибок связанных с работой 
  * невизуальных ActiveX компонент
  IF USED( "TabLists" )=.T. AND SEEK(m.lcAlias, "TabLists" , "TableName" )=.T. AND ;
  		ISRLOCKED(RECNO( "TabLists" ), "TabLists" )=.F. AND RLOCK( "TabLists" )=.T.
    SELECT TabLists
    REPLACE TabLists.LastID WITH TabLists.LastID+ 1 
	IF CursorGetProp('buffering','TabLists')> 1  AND TableUpdate(.F.,.T.,'TabLists')=.F.
	  * Если на служебную таблицу была установлена буферизация и сброс буфера
	  * не удался, то делаю откат буфера, причем результат этого отката уже
	  * не имеет значения
      TableRevert(.F.,'TabLists')
    ELSE
	  lnNewID=TabLists.LastID
	ENDIF
	UNLOCK RECORD RECNO( "TabLists" ) IN TabLists
  ENDIF
  
  * Восстанавливаю исходные настройки среды
  IF m.llIsUsedTabLists=.F.
  	USE IN TabLists
  ENDIF
  SELECT (m.lnArea)
  SET REPROCESS TO m.lcReprocess
  ON ERROR &lcError
  
  RETURN m.lnNewID
ENDFUNC
*************************************************************
*Завершение формирования нового кода записи в указанном или в текущем alias
*************************************************************