Пример
Class oracle.test Extends %RegisteredObject
{
ClassMethod Test(host As %String = "127.0.0.1",port As %Integer = {$$$JDBCGatewayPort}) As %Status
{
  #dim exception As %Exception.StatusException
  set url="jdbc:oracle:thin:@oracleserver:oracleport:scott"
  set username="логин"
  set password="пароль"
  #dim classPath As %ListOfDataTypes=##class(%ListOfDataTypes).%New()
  ; каталог с jar-файлами драйвера Oracle
  do classPath.Insert("C:\JDBC\Oracle\")
  try {
    #dim gateway As %Net.Remote.Gateway=##class(%Net.Remote.Gateway).%New()
    ; подключаемся к шлюзу
    $$$TOE(status,gateway.%Connect(host,port,,,classPath))
    $$$TOE(status,gateway.%ClassForName("oracle.jdbc.OracleDriver"))

    #dim connection As java.sql.Connection=##class(java.sql.DriverManager).getConnection(gateway,url,username,password)
    #dim statement As java.sql.Statement=connection.createStatement()
    #dim rs As java.sql.ResultSet=statement.executeQuery("select ID,UPDSTMP,(SYSDATE-UPDSTMP)*24*60*60 from VOUHDR")
    #dim rsMetaData As java.sql.ResultSetMetaData=rs.getMetaData()
    write !,"Выполнение запроса",!
    write "==============================================",!
    for i=1:1:rsMetaData.getColumnCount() write rsMetaData.getColumnName(i),?$x+10

    write !,"----------------------------------------------",!
    while (rs.next()) {
      for i=1:1:rsMetaData.getColumnCount() write rs.getString(i),?$x+10
    }
    write !,"----------------------------------------------",!

    $$$TOE(status,gateway.%Disconnect())
  } catch exception {
    ; выводим текст ошибки на русском языке
    write $system.Status.GetErrorText(exception.AsStatus(),"ru")
  }
}
}