/// Анализ размера глобала, с анализом размера его подузлов, на указанную вложенность
/// все необходимые параметры будут запршены при запуске
ClassMethod GlobalSize() [ PublicList = (big, DatabaseBlockSize, blksiz, cc, Bytes, Count, gls, lev) ]
{
  s $zt="err"
  do {
    s dir=$$getval("Путь к БД",$zu(12,""))
    w !
    s db=##class(SYS.Database).%OpenId(dir)    
    i '$isobject(db) s dir=""
  } while dir=""
  do {
    s glb=$$getval("Имя глобала","")
    s glb=$tr(glb,"^")
    i glb'="",'$d(@("^|""^^"_dir_"""|"_glb)) s glb=""
  } while glb=""
  s gls=$$getval("Собирать в буфер (будет очищен)","^gls")
  do {
    s lev=$$getval("Глубина расчета","2")
    i $zstrip(lev,"*N")'="" s lev=""
  } while lev=""
  k @gls
  w !
  s Directory=dir /// Папка с БД
  s Name=glb      /// Глобал 
  s rc=$zu(167,6,7,Directory,Name)
  s x=$zu(49,Directory)
  s DatabaseBlockSize=+$p(x,",",$$$blksizpiece) ;размер блока
  /// начальный блок с глобалом
  s PointerBlock=$p(rc,"^",4)
  
  o 63:"^^"_Directory 
  s blk=PointerBlock
  s (Bytes,Count)=0
  s blksiz=DatabaseBlockSize
  s big='(blksiz=$$$2k)
  d ..getsize(blk)
  w !,"Блоков = ",Count
  w !,"Занимаемое место = ",Bytes
  q
err  
  w !,$ze
  q  
getval(mess, def)
  w !,mess_": "_def_" => "
  r res
  i res="" s res=def
  q res
}

/// рекурсивный обход блоков
ClassMethod getsize(blk, haslong = 0) [ Internal, PublicList = (big, DatabaseBlockSize, blksiz, cc, Bytes, Count, gls, lev) ]
{
  q:'blk  
  v blk
  #; тип блока
  s type=$case(DatabaseBlockSize,$$$2k:$$$type2k,:$$$type) 
  w:type'=8 !,$i(cc),?10,blk,?20,type,?30,haslong
  i type=8 {
    #; Блок с данными
    s bts=$$$offsetval(big) // размер блока
    s blkcnt=0
    i haslong {
      #; составной большой блок данных, данные в нескольких блоках
      f j=1:1 {
        s x=$v(j*2,-6) 
        q:x=""  
        s gl=$v(j*2+1,-5)
        i $a(x)=$$$gdviewbiguni(big)!($a(x)=$$$gdviewbigcompact(big))!($a(x)=$$$gdviewbigbin(big)) {
          s blkcnt=$p(x,",",2) 
          s Count=Count+blkcnt // общее количество блоков
          #; размеры блоков
          s bts=bts+((blkcnt-1)*$$$datasize(blksiz)+$p(x,",",3)) 
        }
      }
    } else {
      s blkcnt=1 // в обычном блоке он один
    }
    s t=$i(Count,blkcnt),t=$i(Bytes,bts) 
    try { s gl=$v(1,-5) } catch { s gl="" }
    d ..cnt(gl,bts,blkcnt)
  } elseif type'=1 {
    #; связующие блоки
    f i=1:1 {
      s x=$v(i*2-1,-6)
      q:x=""
      try { s gl=$v(i*2-1,-5) } catch { s gl="" }
      #; связанный с текущим блок
      s datablk=$v(i*2,-5)
      s haslong=0 
      i $p($v(i*2,-6),",",1) {
        s haslong=1
      }
      d ..getsize(datablk,haslong)
      v blk
    }
  }
  q
}

/// запись счетчиков в буфер
ClassMethod cnt(gl, bts, blkcnt = 1) [ Internal, PublicList = (gls, lev) ]
{
  #; считаем в буфере 
  f i=0:1:lev {
    s ind=""
    f j=0:1:i {
      s ind=ind_$lb($qs(gl,j))
    }
    s t=$i(@gls@(ind,"size"),bts)
    s t=$i(@gls@(ind,"cnt"),blkcnt)
  }
  q
}