Public Sub CopyToNewWorkbook()
    Dim ws As Worksheet
    Dim wbCurrent As Workbook
    Dim wbNew As Workbook
    Dim vbc As VBIDE.VBComponent
    Dim strPath As String
    
    Set wbCurrent = ThisWorkbook
    
    ' Создаем новую книгу.
    Set wbNew = Application.Workbooks.Add
    
    strPath = wbCurrent.Path & "\temp.txt"
    
    ' Копируем все листы в новую книгу.
    ' Вместе с содержимым копируется и код.
    For Each ws In wbCurrent.Worksheets
        ws.Copy after:=wbNew.Worksheets(wbNew.Worksheets.Count)
    Next ws
    
    ' Копируем все модули, модули классов,
    ' формы в новую книгу.
    For Each vbc In wbCurrent.VBProject.VBComponents
        If vbc.Type <> vbext_ct_Document Then
            vbc.Export strPath
            wbNew.VBProject.VBComponents.Import strPath
            Kill strPath
        End If
    Next vbc
    
    Set vbc = Nothing
End Sub

Public Sub TestDialog()
    Dim strValue1 As String
    Dim strValue2 As String

    ' В Excel можно воспользоваться методом InputBox
    ' объекта Application.
    strValue1 = Application.InputBox(Prompt:="Введи название:", Type:= 2 )
    
    ' Принимаемые значениея параметра Type.
    ' 0 - A Formula
    ' 1 - A Number
    ' 2 - Text (a string)
    ' 4 - A logical value (True or False)
    ' 8 - A cell reference, as a Range object
    ' 16 An error value, such as #N/A
    ' 64 An array of values
    
    ' Или воспользоваться стандартным InputBox.
    strValue2 = InputBox(Prompt:="Введи название:")

    Debug.Print strValue1
    Debug.Print strValue2
End Sub

Public Sub DeleteShapes()
    Dim sh As Shape
    
    For Each sh In ActiveSheet.Shapes
        sh.Delete
    Next sh
End Sub