Public Sub Creation_Diagram(mvarIngredientMethod As Variant, mlngCountRow As Long)
Dim strWorkbookName As String
Dim xlWorkbook As Excel.Workbook
Dim xlSheetIngr As Excel.Worksheet
Dim strIngredient As String
Dim rstValues As ADODB.Recordset
Dim co As ChartObject
Dim xlChart As Chart
Dim lngRowHeight As Long
Dim lngColumnWidth As Long
Dim intCountCharts As Integer
Dim strDiagSheetName As String
Dim intNomerKoefficient As Integer
Dim lngRow As Long
Dim intCountColumn As Integer
Dim strGroupBy As String
Dim varUnitValue As Variant
Dim intSeriesCollectionCount As Integer
Dim intNumberControlProcedure As Integer
Dim lngChartWidth As Long
       
On Error GoTo ErrorHandler
    
    Application.ScreenUpdating = False
    
    strWorkbookName = ThisWorkbook.Name
    Set xlWorkbook = Application.Workbooks(strWorkbookName)
    Set xlSheetIngr = xlWorkbook.Worksheets(mvarIngredientMethod)
    
    xlSheetIngr.Unprotect "1"
    
    xlSheetIngr.Select
        
    
    'если диаграмма существовала - удаляем ее
    If xlSheetIngr.ChartObjects.Count > 0 Then
        xlSheetIngr.ChartObjects.Delete
    End If
    
    
    lngColumnWidth = xlSheetIngr.Columns(1).Width
    lngRowHeight = xlSheetIngr.Rows(1).Height
    
    'при расчете ширины диаграммы учитываем количество результатов в ряду данных
    intNumberControlProcedure = mlngCountRow - 17
    
    If intNumberControlProcedure > 50 Then  'если результатов больше, чтобы не "наползали" друг на друга
        lngChartWidth = intNumberControlProcedure * 20
    Else
        lngChartWidth = lngColumnWidth * 20
    End If
    
        
    'Построение диаграммы
    Rem Set co = ActiveSheet.ChartObjects.Add(lngColumnWidth * 0.5, lngRowHeight * 10, lngColumnWidth * 20, lngRowHeight * 40)'первоначальный вариант
    Set co = xlSheetIngr.ChartObjects.Add(lngColumnWidth * 0.5, lngRowHeight * 17 + lngRowHeight * mlngCountRow, lngChartWidth, lngRowHeight * 40)
    Application.ScreenUpdating = True
    ActiveWindow.SmallScroll Up:=1000
    ActiveWindow.SmallScroll Down:=mlngCountRow
    
    
    'зададим имя для диаграммы
    Select Case mvarIngredientMethod
        Case "pH (П)"
            strIngredient = "водородного показателя"
        Case "NH4 (Ф)"
            strIngredient = "ионов аммония"
        Case "ХПК (Ф)"
            strIngredient = "ХПК"
        Case "НП (ИК1)"
            strIngredient = "нефтепродуктов"
        Case "Mn (Ф)"
            strIngredient = "марганца"
        Case "НП (Фл)"
            strIngredient = "нефтепродуктов"
        Case "P_общ (Ф)"
            strIngredient = "фосфора общего"
        Case "SO4 (Тб)"
            strIngredient = "сульфат-ионов"
        Case "фенолы (Фл)"
            strIngredient = "фенолов"
        Case "Cl (Т)"
            strIngredient = "хлоридов"
        Case "NH4 (Эф)"
            strIngredient = "катионов аммония"
        Case "NO3 (Эф)"
            strIngredient = "нитрат-ионов"
        Case "SO4 (Эф)"
            strIngredient = "сульфат-ионов"
        Case "АПАВ (Фл)"
            strIngredient = "АПАВ"
        Case "Fe (Ф)"
            strIngredient = "железа общего"
        Case "жиры (Г)"
            strIngredient = "жиров"
        Case "Cu (Ф)"
            strIngredient = "меди"
        Case "NO3 (Ф)"
            strIngredient = "нитрат-ионов"
        Case "NO2 (Ф)"
            strIngredient = "нитрит-ионов"
        Case "со (Г)"
            strIngredient = "сухого остатка"
        Case "PO4 (Ф)"
            strIngredient = "фосфат-ионов"
        
    End Select
    
    Rem Application.ScreenUpdating = False
    
    Select Case mvarIngredientMethod
        Case "pH (П)"
            strDiagSheetName = "Контрольная карта Шухарта." & _
            Chr$(13) & "Контроль повторяемости результатов измерений " & strIngredient & "" & _
            Chr$(13) & "с использованием реальных проб (в абсолютных величинах)"

        Case Else
            strDiagSheetName = "Контрольная карта Шухарта." & _
            Chr$(13) & "Контроль повторяемости результатов измерений " & strIngredient & "" & _
            Chr$(13) & "с использованием реальных проб (в приведенных величинах)"
    End Select
    
    Application.ScreenUpdating = False
    
    With co.Chart
        'определение вида диаграммы (в данном случае - график)
        .ChartType = xlLine
                  
        'добавление ряда данных для результатов контрольных процедур
        .SeriesCollection.Add Source:=xlSheetIngr.Range(xlSheetIngr.Cells(17, 4), _
             xlSheetIngr.Cells(mlngCountRow, 4)), Rowcol:=xlColumns, SeriesLabels:=True
            
        'добавление ряда данных для средней линии
        .SeriesCollection.Add Source:=xlSheetIngr.Range(xlSheetIngr.Cells(17, 12), _
             xlSheetIngr.Cells(mlngCountRow, 12)), Rowcol:=xlColumns, SeriesLabels:=True
                     
        'добавление ряда данных для предела предупреждения
        .SeriesCollection.Add Source:=xlSheetIngr.Range(xlSheetIngr.Cells(17, 13), _
             xlSheetIngr.Cells(mlngCountRow, 13)), Rowcol:=xlColumns, SeriesLabels:=True
            
        'добавление ряда данных для предела действия
        .SeriesCollection.Add Source:=xlSheetIngr.Range(xlSheetIngr.Cells(17, 14), _
             xlSheetIngr.Cells(mlngCountRow, 14)), Rowcol:=xlColumns, SeriesLabels:=True
        
        
        'при расчете ширины области, реально занятой диаграммой, учитываем количество результатов в ряду данных
        .PlotArea.Width = lngChartWidth * 0.85
        .PlotArea.Top = lngRowHeight * 5
        
        
        Select Case mvarIngredientMethod
            Case "pH (П)"
                Rem .Shapes.AddLabel(msoTextOrientationHorizontal, lngColumnWidth * 13.8, _
                    lngRowHeight * 6, lngColumnWidth, lngRowHeight * 2).TextFrame.Characters.Text = "предел действия"
                
                .Shapes.AddLabel(msoTextOrientationHorizontal, lngChartWidth * 0.91, _
                    lngRowHeight * 6, lngColumnWidth, lngRowHeight * 2).TextFrame.Characters.Text = "предел действия"
        
                Rem .Shapes.AddLabel(msoTextOrientationHorizontal, lngColumnWidth * 13.8, _
                    lngRowHeight * 12.5, lngColumnWidth, lngRowHeight * 2).TextFrame.Characters.Text = "предел предупреждения"
                    
                .Shapes.AddLabel(msoTextOrientationHorizontal, lngChartWidth * 0.91, _
                    lngRowHeight * 12.5, lngColumnWidth, lngRowHeight * 2).TextFrame.Characters.Text = "предел предупреждения"
    
                Rem .Shapes.AddLabel(msoTextOrientationHorizontal, lngColumnWidth * 13.8, _
                    lngRowHeight * 25.5, lngColumnWidth, lngRowHeight * 2).TextFrame.Characters.Text = "средняя линия"
                    
                .Shapes.AddLabel(msoTextOrientationHorizontal, lngChartWidth * 0.91, _
                    lngRowHeight * 27, lngColumnWidth, lngRowHeight * 2).TextFrame.Characters.Text = "средняя линия"
                
            Case Else
                Rem .Shapes.AddLabel(msoTextOrientationHorizontal, lngColumnWidth * 13.8, _
                    lngRowHeight * 4, lngColumnWidth, lngRowHeight * 2).TextFrame.Characters.Text = "предел действия"
                    
                .Shapes.AddLabel(msoTextOrientationHorizontal, lngChartWidth * 0.87, _
                    lngRowHeight * 4, lngColumnWidth, lngRowHeight * 2).TextFrame.Characters.Text = "предел действия"
        
                Rem .Shapes.AddLabel(msoTextOrientationHorizontal, lngColumnWidth * 13.8, _
                    lngRowHeight * 11, lngColumnWidth, lngRowHeight * 2).TextFrame.Characters.Text = "предел предупреждения"
                    
                .Shapes.AddLabel(msoTextOrientationHorizontal, lngChartWidth * 0.87, _
                    lngRowHeight * 11, lngColumnWidth, lngRowHeight * 2).TextFrame.Characters.Text = "предел предупреждения"
    
                Rem .Shapes.AddLabel(msoTextOrientationHorizontal, lngColumnWidth * 13.8, _
                    lngRowHeight * 26, lngColumnWidth, lngRowHeight * 2).TextFrame.Characters.Text = "средняя линия"
                    
                .Shapes.AddLabel(msoTextOrientationHorizontal, lngChartWidth * 0.87, _
                    lngRowHeight * 26, lngColumnWidth, lngRowHeight * 2).TextFrame.Characters.Text = "средняя линия"
        End Select
    
    
        'задаем жирные линии
        For intSeriesCollectionCount = 2 To 4
            .SeriesCollection(intSeriesCollectionCount).Border.Weight = xlMedium
        Next intSeriesCollectionCount
    
  
        'Задание свойств диаграммы
             
        .HasTitle = True
        .HasLegend = False
        
        With .ChartTitle
           .Characters.Text = strDiagSheetName
           .Font.Size = 12
           .Top = lngRowHeight * 0.1
        End With
        
        'добавление осей и форматирование подписей к ним
        
        'первичная ось категорий ("идентификаторы" - номера контрольных процедур)
        .HasAxis(xlCategory, xlPrimary) = True
        
        With .Axes(xlCategory, xlPrimary)
            'следующая строка задает отображение значений из первого столбца (идентификаторы)
            .CategoryNames = xlSheetIngr.Range(xlSheetIngr.Cells(18, 1), xlSheetIngr.Cells(mlngCountRow, 1))
            .CategoryType = xlCategoryScale
            .HasTitle = True
            .CrossesAt = 1
            .AxisBetweenCategories = False
            .ReversePlotOrder = False
            .MajorTickMark = xlTickMarkCross
            .TickMarkSpacing = 1
            .TickLabelPosition = xlTickLabelPositionNextToAxis
            .TickLabelSpacing = 1
            .TickLabels.Font.Size = 8
            .TickLabels.NumberFormat = "0"
            .TickLabels.Orientation = xlTickLabelOrientationHorizontal
            .HasMajorGridlines = False
            .HasMinorGridlines = False
        
            With .AxisTitle
                .Caption = "Номера контрольных процедур"
                .Orientation = xlHorizontal
            End With
        End With
                  
      
        'первичная ось значений (результаты контрольных процедур)
        .HasAxis(xlValue, xlPrimary) = True
        With .Axes(xlValue, xlPrimary)
            
            .HasMajorGridlines = False
            .HasMinorGridlines = False
            
            Select Case mvarIngredientMethod
                Case "pH (П)"
                    .TickLabels.NumberFormat = "0.0"
                    .MinimumScale = 0
                    .MaximumScale = 0.3
                    .MinorUnit = 0.1
                    .MajorUnit = 0.1
                    
                Case Else
                    .TickLabels.NumberFormat = "0"
                    .MinimumScaleIsAuto = True
                    .MaximumScaleIsAuto = True
                    .MinorUnit = 0.5
                    .MajorUnit = 1
            End Select
            
            .Crosses = xlAutomatic
            .ReversePlotOrder = False
            .ScaleType = xlLinear
            .DisplayUnit = xlNone
        End With
        
        'установка вида линий
        .SeriesCollection(1).Border.ColorIndex = 11  'данные
        .SeriesCollection(1).MarkerBackgroundColorIndex = 11
        .SeriesCollection(1).MarkerForegroundColorIndex = 11
        .SeriesCollection(1).MarkerStyle = xlSquare
        .SeriesCollection(1).MarkerSize = 3
        
        .SeriesCollection(2).Border.ColorIndex = 50  'сред. линия
        .SeriesCollection(2).Border.Weight = xlThick
        .SeriesCollection(3).Border.ColorIndex = 6  'пред. предупр
        .SeriesCollection(3).Border.Weight = xlThick
        .SeriesCollection(4).Border.ColorIndex = 3  'пред. действия
        .SeriesCollection(4).Border.Weight = xlThick
    End With
    
    xlSheetIngr.Protect "1"
    
    Application.ScreenUpdating = True
    
ErrorHandlerExit:
    Exit Sub
ErrorHandler:
    Application.ScreenUpdating = True
    MsgBox "Creation_Diagram Ошибка №:" & Err.Number & ";Описание:" & Err.Description
    Resume ErrorHandlerExit
End Sub