procedure PrepareSourceFileName(const ANewFile: string);
const
  WORKBOOK_FILE = 'xl\workbook.xml';
var
  tempFile: string;
  tempDir: string;
  tempXml: string;
  fileIndex: Integer;
  zip: TZipFile;
  XMLDoc, aNode, aNodeList: Variant;
  I: Integer;

  function GetFileIndex(AZip: TZipFile): Integer;
  var
    I: Integer;
  begin
    Result := -1;
    for I := 0 to AZip.FileCount - 1 do
    begin
      if ReplaceStr(AZip.FileNames[I], '/', '\') = WORKBOOK_FILE then
      begin
        Result := I;
        Break;
      end;
    end;
  end;

begin
  // фикс для старых эксель-файлов, где могут быть проблемы с именами в области печати (Print_Area)
  // Агафонов Олег, jaydi85@gmail.com
  // пример решения см. на http://www.sql.ru/forum/actualutils.aspx?action=gotomsg&tid=543092&msg=15183800

  // если что-то не так, то будет открываться оригинальный файл
  Self.FSourceFile := ANewFile;
  Self.IsClearTempFile := False;

  zip := TZipFile.Create;
  XMLDoc := Null;
  Screen.Cursor := crHourGlass;
  try
    try
      zip.Open(FSourceFile, TZipMode.zmRead);
    except
      Exit;
    end;
    fileIndex := GetFileIndex(zip);
    if fileIndex < 0 then
    begin
      Exit;
    end;

    // пересоздаем во временный файл
    FreeAndNil(zip);
    tempFile := TPath.GetTempFileName;
    TFile.Copy(FSourceFile, tempFile, True);
    Assert(FileExists(tempFile));

    tempDir := ExtractFileDir(tempFile) + '\' + ReplaceStr(ExtractFileName(tempFile), ExtractFileExt(tempFile), '');
    ForceDirectories(tempDir);

    // распаковываем файлы в xml
    TZipFile.ExtractZipFile(tempFile, tempDir);
    tempXml := tempDir + '\' + WORKBOOK_FILE;
    Assert(FileExists(tempXml));

    // заменяем проблемную строчку
    XMLDoc := CreateOleObject('MSXML2.DOMDocument');
    XMLDoc.async := False;
    XMLDoc.load(tempXml);
    XMLDoc.setProperty('SelectionLanguage', 'XPath');
    XMLDoc.SetProperty('SelectionNamespaces', 'xmlns:wrk="http://schemas.openxmlformats.org/spreadsheetml/2006/main"');

    if not (XMLDoc.parseError.reason = '') then
    begin
      ShowMessage('Не удалось преобразовать файл по причине:' + sLineBreak + sLineBreak + XMLDoc.parseError.reason);
      Exit;
    end;

    // автозамена на другое имя
    //aNodeList := XMLDoc.selectNodes('//wrk:definedName[@name=''_xlnm._FilterDatabase'']');
    aNodeList := XMLDoc.selectNodes('//wrk:definedName[@name=''_xlnm.Print_Area'']');
    for I := 0 to aNodeList.Length - 1 do
    begin
      aNode := aNodeList.item[I];
      aNode.setAttribute('name', '_xlnm.SomePrintAreaFix');
    end;
    XMLDoc.save(tempXml);

    // файл готов, пакуем обратно
    TZipFile.ZipDirectoryContents(tempFile, tempDir);
    Assert(FileExists(tempXml));

    // подчищаем
    TDirectory.Delete(tempDir, True);

    // ВСЕ ОК
    Self.FSourceFile := tempFile;
    Self.IsClearTempFile := True;
  finally
    FreeAndNil(zip);
    XMLDoc := Null;
    Screen.Cursor := crDefault;
  end;
end;