Sub AddComment()
' ZVI:2015-06-06 http://www.sql.ru/forum/1159087/primechanie-k-vhodyashhemu-pismu-outlook
' Put this code into any Outlook VBA module.
' Customize Ribbon to add this macro with its button to the QAT.
' In Outlook mail select any text and click on macro button to insert a comment.
  
  Const wdNoProtection = -1
  Dim i As Long, j As Long
  
  ' Trap errors
  On Error GoTo exit_
  
  ' Save start & end positions of selection
  With ActiveInspector.WordEditor.Application.Selection.Range
    i = .Start
    j = .End
  End With
  
  ' Change TEXT format of the mail to the HTML one to allow commenting
  With ActiveInspector.CurrentItem
    If .BodyFormat = olFormatPlain Then
      .BodyFormat = olFormatHTML
    End If
  End With

  ' Allow mail editing, restore selection, add comment to the selection
  With ActiveInspector.WordEditor ' equal to With Word.Document
    If .ProtectionType <> wdNoProtection Then .UnProtect
    .Range(i, j).Select
    .Comments.Add(.Application.Selection.Range).Edit
  End With

exit_:
  
  ' Show reason of error
  If Err Then MsgBox Err.Description, vbCritical, "Can't insert the comment! Error #" & Err.Number

End Sub