Option Explicit
Option Base 0

Sub expToFixedSmart()
    '$conditions
    Const I_HEADER& = 4&, S_FOOTER$ = "Èòîãî:", S_FORMAT$ = "#0.00"
    '$fuse
    Const I_MAX_BLANK& = 3&, I_MAX_ROW& = 1000&
    
    Dim f%, sExpFileName$
    Dim a, s$, s2$, k&, k2&, iLen&
    
    '$datatableconditions
    a = Array(6&, 13&, 37&)
    
    '$expfilename
    sExpFileName = Left$(ThisWorkbook.Name, InStrRev(ThisWorkbook.Name, ".") - 1) & "_exp.txt"
    ChDrive Left$(ThisWorkbook.Path, 1)
    ChDir ThisWorkbook.Path
    
    
    f = FreeFile
    Open sExpFileName For Output Access Write As #f
    
    With ThisWorkbook.Worksheets(1)
        '$header
        For k = 1 To I_HEADER
            s = .Cells(k, 1).Value2
            Print #f, s
        Next k
        
        k = I_HEADER + 1: k2 = 0
        
        '$datatable
        Do Until _
            0 = StrComp(S_FOOTER, .Cells(k, 1).Value2) Or _
            I_MAX_ROW < k Or _
            I_MAX_BLANK < k2
            
            iLen = Len(.Cells(k, 1).Value2)
            If iLen > 0 Then
                'col#1
                s = .Cells(k, 1).Value2 & Space(a(0) - iLen)
                
                'col#2
                iLen = Len(.Cells(k, 2).Value2)
                s = s & .Cells(k, 2).Value2 & Space(a(1) - iLen)
                
                'col##3,4
                s = s & .Cells(k, 3): s2 = Format$(.Cells(k, 4), S_FORMAT)
                iLen = Len(s) + Len(s2)
                s = s & Space(a(2) - iLen) & s2
                
                k2 = 0
                
            Else:   s = "": k2 = k2 + 1
            End If
            
            Print #f, s
            k = k + 1
        Loop
        
        '$footer|$err
        If StrComp(S_FOOTER, .Cells(k, 1).Value2) = 0 Then
            s = .Cells(k, 1).Value2 & "  " & Format$(.Cells(k, 4).Value2, S_FORMAT)
        ElseIf I_MAX_BLANK < k2 Then
            s = "E: footer row not found, MAX_BLANK reached"
        Else
            s = "E: footer row not found, MAX_ROW reached"
        End If
        
        Print #f, s
    End With
    
    Close #f
    Shell "notepad " & sExpFileName, vbNormalFocus
    
End Sub