SELECT t1.Дата, t1.Номер, t1.Статус,
(SELECT  COUNT(t2.Дата) as C_N
From range0 AS t2
WHERE t1.Номер=t2.Номер AND t1.Дата<t2.Дата AND t2.Статус>0 ) AS d_t
FROM range0 AS t1
 WHERE t1.Статус>0
GROUP BY t1.Дата, t1.Номер, t1.Статус

Public Function ADO_R_Dmitry(ByVal StrSql$, ByVal FilePath$, ByVal OutputRange As Range, _
ByVal FieldsName As Boolean, ByVal OutputFieldsName As Boolean)
'==============================================================================
'*Описание функции : Возвращает набор записей Recordset с первой ячейки адреса,
'* указанного диапазона.
'*strSql - Конструкция SQL запроса.
'* FilePath - Полный путь к файлу включая имя и расширение.
'* OutputRange - адрес ячеки с которой начинается вывод данных.
'* FieldsName - используются или нет заголовки столбцов (True - False)
'* OutputFieldsName - вывод данных с заголовками или без (True - False), _
'==============================================================================
'* Автор R Dmitry (Дмитрий Русак dg_rusak@mail.ru skype: RDG_Dmitry) |
'* WM:_R269866874234 U144446690328 |
'==============================================================================
Dim sCon As String, FieldName As String
Dim rs As Object, cn As Object
Set rs = CreateObject("ADODB.Recordset")
Set cn = CreateObject("ADODB.Connection")
If FieldsName Then FieldName = "Yes" Else FieldName = "No"
Select Case Val(Application.Version)

Case Is < 12
sCon = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & FilePath _
& ";Extended Properties=""Excel 8.0;HDR=" & FieldName & ";IMEX=1"";"
Case Is >= 12
sCon = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & FilePath _
& ";Extended Properties=""Excel 12.0;HDR=" & FieldName & ";IMEX=1"";"
End Select

cn.Open sCon
If Not cn.State = 1 Then Exit Function
Set rs = cn.Execute(StrSql)
If Not FieldsName Then OutputFieldsName = False
If OutputFieldsName Then
For i = 0 To rs.Fields.Count - 1
OutputRange.Offset(0, i) = rs.Fields(i).Name
Next
Set OutputRange = OutputRange.Offset(1, 0)
End If
DoEvents
OutputRange.CopyFromRecordset rs
rs.Close: cn.Close
Set cn = Nothing: Set rs = Nothing
End Function

Sub GetFileName(ByRef OtputPath)
    With Application.FileDialog(msoFileDialogFilePicker)
        .Show
        If .SelectedItems.Count > 0 Then Set OtputPath = .SelectedItems
    End With
End Sub

Sub test()
strSql2 = "SELECT * FROM [Ввод$]"
GetFileName tt
If IsEmpty(tt) Then Exit Sub
Call ADO_R_Dmitry(strSql2, tt(1), Sheets(1).[a1], True, True)
End Sub