' ==============================================
' скрипт showfiles.vbs
' отображение файлов в каталоге и его подкаталогах
' с подсчетом кол-ва и суммарного размера файлоф
' ==============================================
option explicit

' папка
const S_PATH = "D:\PROGRAM_FILES\lazarus\"

' файл журнала
const S_LOG = "d:\tmplog.log" 		' ограничение - путь без пробелов
'const S_LOG = """d:\tmp2 log.log""" 	' путь содержит пробелы - экранировать кавычками

'фильтр команды find
const S_FIND = "файлов"      ' для русскоязычной Windows
'const S_FIND = "files"      ' для аглицкой Windows

' паттерн поиска в выводе команды dir|find для определения кол-ва и суммарного размера файлов
'const S_SIZE_PATTERN = "(.+) файлов (.+) байт" 	' для локализованной РУССКОЙ Windows
const S_SIZE_PATTERN = "([ 0-9]+)\D+(.+[0-9])"		' для любой(?) локализации...

dim shell,wshexec,instream,outstream,str
dim re,cm
dim quantity,sizeem

dim s_cmd_size,s_cmd_files, s_cmd


'### debug only
dim t: t = timer: wscript.echo "start: "& time()


s_cmd_files ="@for /f ""tokens =*"" %a in ('dir /s/b/a-d """& S_PATH &"""') do @echo.%a...>>"& S_LOG
' если не надо '...' после имени файла, то можно проще (оно и быстрее будет):
's_cmd_files ="dir /s/b/a-d """& S_PATH &""">>"& S_LOG

s_cmd_size = "dir /s/a-d """& S_PATH &"""|find "" "& S_FIND &"""&&exit"

set shell = createobject("wscript.shell")

s_cmd = "cmd /k @echo off&&chcp 1251&&echo."& cstr(date()) &" "& cstr(time()) &" Opening...>>"& S_LOG
set wshexec = shell.exec(s_cmd)

set instream = wshexec.stdin
instream.writeline s_cmd_files
instream.writeline s_cmd_size
set instream = nothing

set outstream = wshexec.stdout
str = vbnullstring
do until outstream.atendofstream
  str = trim(outstream.readline())
loop

set outstream = nothing
set wshexec = nothing

set re = createobject("vbscript.regexp")
re.pattern = S_SIZE_PATTERN
set cm = re.execute(str)

if cm.count<1 then
  str = "Quantity: 0, size 0 B"
else
  quantity = fix(cm(0).submatches(0))
  sizeem = fix(cm(0).submatches(1))

  if sizeem<1024 then
    str = sizeem & " B"
  elseif sizeem<1024*1024 then
    str = round(sizeem/1024,3) & " KB"
  else
    str = round((sizeem/1024)/1024,3) & " MB"
  end if
  
  str = "Quantity: "& quantity &", size: "& str
end if

set cm = nothing
set re = nothing

s_cmd = "cmd /c @echo off&&chcp 1251&&("& "echo."& str &">>"& S_LOG &")"
s_cmd = s_cmd &"&&("& "echo."& cstr(date()) &" "& cstr(time()) &" Closing...>>"& S_LOG &")"
set wshexec = shell.exec(s_cmd)


'### debug only
wscript.echo "end:   "& time(): wscript.echo "timer: "& fix(timer() - t)


wscript.quit