Public Function FiltersCriteria(Optional varSheet As Worksheet) As String
Dim objWsht As Worksheet, objF As Filter, I As Long, J As Long, strOut As String, FlagCount As Boolean

If varSheet Is Nothing Then Set objWsht = ActiveSheet Else Set objWsht = varSheet
If Not objWsht.AutoFilter Is Nothing Then
  I =  0 : strOut = ""
  For Each objF In objWsht.AutoFilter.Filters
    I = I +  1 
    If objF.On Then
      strOut = strOut & " Колонка '" & objWsht.AutoFilter.Range.Cells( 1 , I).Value & "' "
      FlagCount = True
      If Val(Application.Version) >  11  Then 'т.к. в Excel2007 на даты фильтр странный
        If objF.Count =  0  Then
          strOut = strOut & "массив дат"
          FlagCount = False
        End If
      End If
      If FlagCount Then
        If VarType(objF.Criteria1) >  8192  Then
          For J =  1  To UBound(objF.Criteria1)
            If J >  1  Then strOut = strOut & ","
            If J >  3  Then strOut = strOut & "...": Exit For
            strOut = strOut & objF.Criteria1(J)
          Next J
        Else
          If VarType(objF.Criteria1) <>  9  Then strOut = strOut & objF.Criteria1
        End If
        If objF.Operator Then
          strOut = strOut & " " & Choose(objF.Operator, _
            "И", "ИЛИ", "", "", "", _
            "", "", "на цвет ячеек", "на цвет шрифта", "на значок условного форматирования", _
            "динамический фильтр", "нет цвета ячеек(нет заливки)", "нет цвета шрифта(Auto)", "нет значка условного форматирования") & " "
          Select Case objF.Operator
          Case  1 ,  2 
            strOut = strOut & objF.Criteria2
          End Select
        End If
      End If
      strOut = strOut & ";"
    End If
  Next objF
End If
FiltersCriteria = strOut
End Function 'FiltersCriteria