'Непонятки какие-то с автопоименованием QueryTable.
'Если что-то будет не так, лучше дать другое имя- при смене имени все вроде начинает работать,
'потом если посоздавать еще таблиц, то опять перестает...
Public Const QueryTableName As String = "QueryTableData"

Sub bttnQueryTableRefresh()
    If IsQueryTableExists(QueryTableName) Then
        With ActiveSheet.QueryTables(QueryTableName)
            .CommandText = MakeSQL()
            .Refresh BackgroundQuery:=False
        End With
    End If
End Sub

Sub bttnQueryTableCreate()
    Dim q As QueryTable
    Dim n As Name
    With ActiveWorkbook.Sheets("Data") 'Имя листа на котором QueryTable
        For Each q In .QueryTables
            q.Delete
        Next q
        For Each n In .Names 'Не боимся- удаляются только локальные имена :-)
            n.Delete
        Next n
    End With
    With ActiveWorkbook.Sheets("Data").QueryTables.Add(Connection:=Array( _
            "ODBC; " & _
            "DRIVER={SQLite2009 Pro ODBC Driver}; " & _
            "Filename=" & Range("DB.Path").Text & ";"), _
            Destination:=Range("DB.InsertQueryTableHere")) 'Для удобства называем ячейку
        .Name = QueryTableName
        .FieldNames = True
        .RowNumbers = True
        .RefreshPeriod =  0 
        .AdjustColumnWidth = False
        .FillAdjacentFormulas = True
        .PreserveFormatting = True
        .BackgroundQuery = True
        .RefreshStyle = xlOverwriteCells
        '.PreserveColumnInfo = True
        '.SaveData = True
        '.SavePassword = False
        '.RefreshOnFileOpen = False
        .CommandText = MakeSQL() 'Если не сделать, то не создастся
        .Refresh BackgroundQuery:=False
    End With
End Sub

Function MakeSQL() As Variant
    MakeSQL = _
        Range("SQL.SELECT").Value & Chr( 13 ) & Chr( 10 ) & _
        Range("SQL.FROM").Value & Chr( 13 ) & Chr( 10 ) & _
        Range("SQL.WHERE").Value & Chr( 13 ) & Chr( 10 ) & _
        Range("SQL.ORDER").Value
End Function

Function IsQueryTableExists(s As String) As Boolean
    Dim q As QueryTable
    IsQueryTableExists = False
    For Each q In ActiveSheet.QueryTables 'Предполагаем, что кнопка Refresh находится на том же листе
        If StrComp(s, q.Name,  1 ) =  0  Then
            IsQueryTableExists = True
            Exit Function
        End If
    Next q
End Function