Sub ПолучитьСводкуПокупателей()
'Формирует сводную таблицу (сальдовую ведомость) по покупателям

    Application.ScreenUpdating = False
    
    Dim pt As PivotTable
    Set pt = GetPivotTable("СводкаПокупателей", "Счета Покупок и Продаж.xls", "ЖурналДоходов")
    
    On Error Resume Next
    
    With pt
        .AddFields RowFields:=Array("Фирма", "Данные")
        .CalculatedFields.Add "Сальдо Дт", "=ROUND(MAX(0,Дт-Кт),2)", True
        .CalculatedFields.Add "Сальдо Кт", "=ROUND(MAX(0,Кт-Дт),2)", True
        
        .PivotFields("Фирма").PivotItems("(пусто)").Visible = False
        
        With .PivotFields("Сальдо Дт")
            .Orientation = xlDataField
            .Caption = "Отгружено"
            .Function = xlSum
            .NumberFormat = "# ##0.00"
        End With
        
        With .PivotFields("Сальдо Кт")
            .Orientation = xlDataField
            .Caption = "Предоплата"
            .Function = xlSum
            .NumberFormat = "# ##0.00"
        End With
        
        With .DataPivotField
            .Orientation = xlColumnField
            .Position =  1 
        End With
        
        .RowGrand = False
        .ColumnGrand = False
    
    End With
    
    ActiveWorkbook.ShowPivotTableFieldList = False
    Application.ScreenUpdating = True
    ActiveWindow.DisplayZeros = False
    
End Sub

Private Function GetPivotTable( _
                                ByVal ИмяСводнойТаблицы As String, _
                                ByVal ИмяФайлаДанных As String, _
                                ByVal ИмяДиапазонаДанных As String _
                                ) As PivotTable
    
    strTableName = ИмяСводнойТаблицы
    strDataFile = ИмяФайлаДанных
    strRangName = ИмяДиапазонаДанных
    strSourceData = ActiveWorkbook.Path & Application.PathSeparator & _
                    strDataFile & "!" & strRangName
    
    Dim ptCache As PivotCache
    Dim pt As PivotTable
    
    Set ptCache = ActiveWorkbook.PivotCaches.Add( _
        SourceType:=xlDatabase, _
        SourceData:=strSourceData)
    
    Set pt = ptCache.CreatePivotTable( _
        TableDestination:=ActiveCell, _
        TableName:=strTableName, _
        DefaultVersion:=xlPivotTableVersion10)
        
    Set GetPivotTable = pt

End Function