@NikИсходя из этого , следующая формула, хоть и длинее по форме записи, но быстрее по вычислению :-)
=СУММПРОИЗВ(СУММ((D4:D10=I3)*(E4:G10)))
(не формула массива)

Мои промеры этого не подтверждают - в XL2003, 10.000 ячеек, разницы практически никакой, да и нелогично вроде :-(

Неясно почему никто не предлагает вот это: =СУММПРОИЗВ((D4:D10=I3)*(E4:G10))
В отличие от =СУММПРОИЗВ(--(D4:D10=I3);E4:G10), оно работать будет :-)

KL
[MVP - Microsoft Excel]

Эта будет слегка побыстрее чем предыдущие, но зато летучая, для диапазонов, заданых в примере:

=СУММ(СУММЕСЛИ($D$4:$D$10;$I$3;СМЕЩ($E$4:$E$10;;{0:1:2}))) на 20% быстрее

а эта даже немного медленнее:

=СУММПРОИЗВ(СУММЕСЛИ($D$4:$D$10;$I$3;СМЕЩ($E$4:$E$10;;СТРОКА(ДВССЫЛ("1:"&ЧИСЛСТОЛБ($E$4:$G$10)))-1))) на 4% медленнее

Зато простое увеличение диапазона таблицы с 6 строк до 34 дает увеличение преимущества в скорости в половину:

=СУММ(СУММЕСЛИ($D$4:$D$10;$I$3;СМЕЩ($E$4:$E$10;;{0:1:2}))) на 57% быстрее

=СУММПРОИЗВ(СУММЕСЛИ($D$4:$D$10;$I$3;СМЕЩ($E$4:$E$10;;СТРОКА(ДВССЫЛ("1:"&ЧИСЛСТОЛБ($E$4:$G$10)))-1))) на 45% быстрее

и это при том, что я намеренно поставил искомое значение последним в таблице, т.к. насколько я понимаю, чем ближе оно к началу, тем выше быстродействие СУММЕСЛИ.

Так-что, выражаясь крылатой фразой, "выбирай, но осторожно..., но выбирай..., но осторожно."

KL
[MVP - Microsoft Excel]

Работа над ошибками:

Начиная со слова "Зато", следует читать так:
KL (XL)...Зато простое увеличение диапазона таблицы с 6 строк до 34 дает увеличение преимущества в скорости в половину:

=СУММ(СУММЕСЛИ($D$4:$D$ 38 ;$I$3;СМЕЩ($E$4:$E$ 38 ;;{0:1:2}))) на 57% быстрее

=СУММПРОИЗВ(СУММЕСЛИ($D$4:$D$ 38 ;$I$3;СМЕЩ($E$4:$E$ 38 ;;СТРОКА(ДВССЫЛ("1:"&ЧИСЛСТОЛБ($E$4:$G$ 38 )))-1))) на 45% быстрее...

@Nik KL (XL)Неясно почему никто не предлагает вот это: =СУММПРОИЗВ((D4:D10=I3)*(E4:G10))
Потому, что при одном аргументе у СУММПРОИЗВ() она вырождается в обычную {=СУММ(...)} и по скорости от неё не отличается.

Насколько мне известно, при прочих равных, конструкция СУММПРОИЗВ() имеет как минимум два преимущества перед {=СУММ(...)}:

- не требует ввода через CTRL+SHIFT+ENTER
- считает на 15-20% быстрее

недостатки:

- размер файла растет быстрее, чем с формулой массива

KL
[MVP - Microsoft Excel]

@Nik=-СУММПРОИЗВ(-(D4:D10*{1;1;1}=I3);E4:G10)
=СУММ(СУММЕСЛИ(B4:D10;I3;E4:G10)), где в ячейках B4:С10 стоит формула "=$D:$D" или "=$D4"
Несмотря на использование дополнительных ячеек, я пожалуй отдам предпочтение второму решению, тем более, что функция СУММ() здесь как бы и никчему:

=СУММЕСЛИ(B4:D10;I3;E4:G10) , где в ячейках B4:С10 стоит формула "=$D4"