Sheets("Сводный").Cells(k,l)=Sheets(sh).cells(i,j)

Sheets("Сводный").Range("A101:N199").value=Sheets(sh).Range("A2:N100").value

Sub Выбрать_данные()
Dim NewLine As Integer, Col As Integer, ToSheet As Worksheet
Dim Lrow As Long, Frow As Long
Dim ws As Worksheet, FromRangeName As String
   
  
 Application.ScreenUpdating = False
 Application.Calculation = xlCalculationManual
   
   '№ Последнего столбца для консолидации, первый считается "A".
   'Дейсвует как для исходных данных, так и для итоговых
   Col =  20 
   'Первая строка в которую заполняются значения
   NewLine =  3 
   'Лист на который будем копировать
   Set ToSheet = ThisWorkbook.Sheets("Лист2")
   'Открытие листа куда заполняются данные
   ToSheet.Select
   'Очистка предыдущих данных
   Range(Cells(NewLine,  1 ), Cells(Rows.Count, Col)).Clear

   'первая строка в диапазоне, которую нужно копировать
   Frow =  3 
      
    For Each ws In ThisWorkbook.Worksheets
     If ws.Name <> ToSheet.Name Then
      'Имя Диапазона, в котором искать последнюю строку
      FromRangeName = Range(Cells( 1 ,  1 ).Address, Cells(Rows.Count, Col).Address).Address
       
       On Error Resume Next
       'нахождение последней строки в диапазоне
        Lrow = ws.Range(FromRangeName).Find(What:="*", SearchDirection:=xlPrevious, SearchOrder:=xlByRows).Row
        If Err.Number =  0  Then
       On Error GoTo  0 
         'Копирование значений диапазона
          ToSheet.Range(Cells(NewLine,  1 ).Address, Cells(NewLine - Frow + Lrow, Col).Address).Value = _
            ws.Range(Cells(Frow,  1 ).Address, Cells(Lrow, Col).Address).Value
          NewLine = NewLine - Frow + Lrow +  1 
        End If
     End If
    Next ws
   
 Application.ScreenUpdating = True
 Application.Calculation = xlCalculationAutomatic
End Sub