В ячейке [E3] пишем след. формулу и копируем ее вниз:

=ЕСЛИ(B3=1;ЕСЛИ(СЧЁТ($B$2:B2)=0; СУММ($A$3:A3);СУММ(ИНДЕКС($A$3:A3;ПОИСКПОЗ(9E+307;$B$2:B2)):ИНДЕКС($A$3:A3;СТРОКА()-СТРОКА($A$3)+1)));"")

KL
[MVP - Microsoft Excel]

DeggasadЯ конечно не вовремя, но не зря же я писал, Вот ещё вариант

=ЕСЛИ(B3="";"";ЕСЛИ(ЕНД(ПОИСКПОЗ(9E+307;$B$1:B2));СУММ($A$1:A3);СУММ(СМЕЩ(A3;-(СТРОКА()-ПОИСКПОЗ(9E+307;$B$1:B2)-1);0;СТРОКА()-ПОИСКПОЗ(9E+307;$B$1:B2)))))

Привет Deggasad,

У этой формулы помимо длинны есть еще один недостаток - она летучая из-за функции СМЕЩ, а значит будет пересчитываться по поводу и без повода :-)

KL
[MVP - Microsoft Excel]

Deggasad romajan DeggasadЯ конечно не вовремя, но не зря же я писал, Вот ещё вариант

=ЕСЛИ(B3="";"";ЕСЛИ(ЕНД(ПОИСКПОЗ(9E+307;$B$1:B2));СУММ($A$1:A3);СУММ(СМЕЩ(A3;-(СТРОКА()-ПОИСКПОЗ(9E+307;$B$1:B2)-1);0;СТРОКА()-ПОИСКПОЗ(9E+307;$B$1:B2)))))

Функция ПОИСКПОЗ(9E+307;$B$1:B5) возвращает номер строки последней единицы в столбце В.
А что означатет 9E+307?

Что-то типа самого большого числа!

Если точнее, то это попытка приблизиться к самому большому (а значит наименее вероятному) возможному числу в Excel [9,99999999999999E+307] и как можно короче. Суть именно в том, чтобы функция ПОИСКПОЗ не нашла числа столь же большого, что и искомое, а в таком случае следующие формулы возаращают последнее числовое значение в списке:

= ПРОСМОТР (Арг1; 9E+307 )
= ПРОСМОТР (Арг1; 9E+307 ;Арг3)
= ВПР ( 9E+307 ;Арг2;Арг3; ИСТИНА )
= ВПР ( 9E+307 ;Арг2;Арг3; 1 )
= ВПР ( 9E+307 ;Арг2;Арг3)
= ГПР ( 9E+307 ;Арг2;Арг3; ИСТИНА )
= ГПР ( 9E+307 ;Арг2;Арг3; 1 )
= ГПР ( 9E+307 ;Арг2;Арг3)
= ПОИСКПОЗ ( 9E+307 ;Арг2; ИСТИНА )
= ПОИСКПОЗ ( 9E+307 ;Арг2; 1 )
= ПОИСКПОЗ ( 9E+307 ;Арг2; -1 )
= ПОИСКПОЗ ( 9E+307 ;Арг2)

Для текстовых значений можно использовать след. формулы:

= ПРОСМОТР (Арг1; "яяяяяяя" )
= ПРОСМОТР (Арг1; "яяяяяяя" ;Арг3)
= ВПР ( "яяяяяяя" ;Арг2;Арг3; ИСТИНА )
= ВПР ( "яяяяяяя" ;Арг2;Арг3; 1 )
= ВПР ( "яяяяяяя" ;Арг2;Арг3)
= ГПР ( "яяяяяяя" ;Арг2;Арг3; ИСТИНА )
= ГПР ( "яяяяяяя" ;Арг2;Арг3; 1 )
= ГПР ( "яяяяяяя" ;Арг2;Арг3)
= ПОИСКПОЗ ( "яяяяяяя" ;Арг2; ИСТИНА )
= ПОИСКПОЗ ( "яяяяяяя" ;Арг2; 1 )
= ПОИСКПОЗ ( "яяяяяяя" ;Арг2; -1 )
= ПОИСКПОЗ ( "яяяяяяя" ;Арг2)

Deggasad "яяяяяяя" - именно 7 "я" или это просто пример???

Кол-во "я" - не принципиально. Их должно быть достаточно для того, чтобы избежать случайных совпадений.

KL
[MVP - Microsoft Excel]

Deggasad KL (XL) Deggasad "яяяяяяя" - именно 7 "я" или это просто пример???

Кол-во "я" - не принципиально. Их должно быть достаточно для того, чтобы избежать случайных совпадений.

KL
[MVP - Microsoft Excel]

Понял, спасибо!
Но именно "я" правильно я понимаю? И Важен ли Регистр?

Нужен знак с самым высоким Character ID, регистр не важен.

KL
[MVP - Microsoft Excel]