Sub LoadHugeFile()
    Const intLines =  10 
    Dim objFSO As Scripting.FileSystemObject, objHugeFile As Scripting.TextStream
    Dim intLinesAmount%, strTemp$, intSheetsAmount%, intCurrentSheet%, intCurrentLine%, intCurrentRow%
    Set objFSO = New Scripting.FileSystemObject
    Set objHugeFile = objFSO.OpenTextFile("C:\Temp\AXE.vbs", ForReading)
    intLinesAmount =  0 
'Подсчитываем количество строк в файле, чтобы создать необходимое количество листов
    Do While Not objHugeFile.AtEndOfStream
        strTemp = objHugeFile.ReadLine
        intLinesAmount = intLinesAmount +  1 
    Loop
    objHugeFile.Close
'Подсчет необходимого количества листов
    If Int(intLinesAmount / intLines) <> intLinesAmount / intLines Then
        intSheetsAmount = intLinesAmount \ intLines +  1 
    Else
        intSheetsAmount = Int(intLinesAmount / intLines)
    End If
'Удаляем все лишние листы, т.е. оставляет только один лист
    Application.DisplayAlerts = False
    Do While ActiveWorkbook.Sheets.Count >  1 
        ActiveWorkbook.Sheets( 1 ).Delete
    Loop
    Application.DisplayAlerts = True
'Добавление необходимого количества листов
    Do While ActiveWorkbook.Sheets.Count <> intSheetsAmount
        Sheets.Add
    Loop
'Загрузка файла
    Set objHugeFile = objFSO.OpenTextFile("C:\Temp\AXE.vbs", ForReading)
    intCurrentSheet =  1 : intCurrentLine =  0 : intCurrentRow =  0 
    Do While Not objHugeFile.AtEndOfStream
        strTemp = objHugeFile.ReadLine
        intCurrentLine = intCurrentLine +  1 
        intCurrentRow = intCurrentRow +  1 
        If intCurrentLine > intLines Then
            intCurrentLine =  1 
            intCurrentSheet = intCurrentSheet +  1 
            intCurrentRow =  1 
        End If
        Sheets(intCurrentSheet).Cells(intCurrentRow,  1 ) = strTemp
    Loop
    objHugeFile.Close
    Set objHugeFile = Nothing
    Set objFSO = Nothing
End Sub