Public Sub CreateAccessDatabaseADO()
    Dim cat As ADOX.Catalog
    Dim tbl As ADOX.Table
    Dim cnn As ADODB.Connection
    
    Set cat = New ADOX.Catalog
    Set tbl = New ADOX.Table
    Set cnn = New ADODB.Connection
    
    If Dir("D:\1\dbAdo.mdb") <> "" Then Kill "D:\1\dbAdo.mdb"
    
    cat.Create "Provider=Microsoft.Jet.OLEDB.4.0;" & _
      "Data Source=D:\1\dbAdo.mdb"

    tbl.Name = "Table1"
    tbl.Columns.Append "Id", adInteger
    tbl.Columns.Append "LastName", adVarWChar,  50 
    
    cat.Tables.Append tbl
    
    cnn.Open "Provider=Microsoft.Jet.OLEDB.4.0;" & _
      "Data Source=D:\1\dbAdo.mdb"
    cnn.Execute "INSERT INTO Table1 (Id, LastName) VALUES (1, 'Иванов')"
       
    cnn.Close
    
    Set tbl = Nothing
    Set cat = Nothing
    Set cnn = Nothing
End Sub

Public Sub CreateAccessDatabaseDAO()
    Dim db As DAO.Database

    If Dir("D:\1\dbDao.mdb") <> "" Then Kill "D:\1\dbDao.mdb"
    
    Set db = CreateDatabase("D:\1\dbDao.mdb", dbLangCyrillic, dbEncrypt)

    db.Execute "CREATE TABLE Table1 (Id Int, LastName CHAR (50))", _
      dbFailOnError
    db.Execute "INSERT INTO Table1 (Id, LastName) VALUES (1, 'Иванов')", _
      dbFailOnError
    
    db.Close
    Set db = Nothing
End Sub