Private intI As Integer
Private arr() As Variant

Sub HideCommandBars()
    Dim cb As CommandBar
    Dim cbButton As CommandBarButton

    For Each cb In Application.CommandBars
        If cb.Visible Then
            ReDim Preserve arr(intI)
            arr(intI) = cb.Name
            intI = intI +  1 
            cb.Visible = False
        End If
    Next
    
    Application.CommandBars("Worksheet menu bar").Enabled = False
    
    Set cb = Application.CommandBars.Add(Name:="Custom CommandBar", _
      Position:=msoBarTop, _
      MenuBar:=False, _
      Temporary:=True)
    
    Set cbButton = cb.Controls.Add(Type:=msoControlButton, _
      Temporary:=True)
    
    With cbButton
        .Caption = "&Сохранить"
        .FaceId =  3 
        .Style = msoButtonIcon
        .Tag = "Save"
        .OnAction = "SaveBook"
        .TooltipText = "Сохранить рабочую книгу"
    End With
    
    cb.Visible = True
      
    Set cbButton = Nothing
    Set cb = Nothing
End Sub

Sub ShowCommandbars()
    For intI = LBound(arr) To UBound(arr)
        Application.CommandBars(arr(intI)).Visible = True
    Next
    Application.CommandBars("Worksheet menu bar").Enabled = True
End Sub

Sub AddCommandBarButton()
    Dim cb As CommandBar
    Dim cbb As CommandBarButton
    
    Set cb = CommandBars.Add( _
      Name:="Custom", _
      Position:=msoBarTop, _
      Temporary:=True)
      
    Set cbb = cb.Controls.Add( _
      Type:=msoControlButton, _
      Temporary:=True)
    
    cbb.FaceId =  59 
    cbb.OnAction = "Test"
      
    cb.Visible = True
    
    Set cbb = Nothing
    Set cb = Nothing
End Sub

Sub Test()
    MsgBox "Test"
End Sub