'LbDateTime
Private Const c_frmdateA As String = "mm/dd/yyyy"
Private Const c_frmdate As String = "dd.mm.yyyy"
Private Const c_frmtime As String = "hh:mm:ss"

Private m_date As Date

Private Sub Class_Initialize()
    m_date = Now()
End Sub

Public Function DaysInMonth(Optional mnth As Integer =  0 , Optional yr As Integer =  0 ) As Integer
    If mnth =  0  Then mnth = TheMonth
    If yr =  0  Then yr = TheYear
    DaysInMonth = DateSerial(yr, mnth +  1 ,  1 ) - DateSerial(yr, mnth,  1 )
End Function
Private Function Reduce(sec As Integer, min As Integer, hr As Integer, dy As Integer, mnth As Integer, yr As Integer) As Date
    Reduce = DateSerial(yr, mnth, dy) + TimeSerial(hr, min, sec)
End Function

Public Property Get TheSecond() As Integer
    TheSecond = Second(m_date)
End Property
Public Property Let TheSecond(ByVal vNewValue As Integer)
    On Error GoTo wrong
    m_date = Reduce(vNewValue, Minute(m_date), Hour(m_date), Day(m_date), Month(m_date), Year(m_date))
wrong:
End Property

Public Property Get TheMinute() As Integer
    TheMinute = Minute(m_date)
End Property
Public Property Let TheMinute(ByVal vNewValue As Integer)
    On Error GoTo wrong
    m_date = Reduce(Second(m_date), vNewValue, Hour(m_date), Day(m_date), Month(m_date), Year(m_date))
wrong:
End Property

Public Property Get TheHour() As Integer
    TheHour = Hour(m_date)
End Property
Public Property Let TheHour(ByVal vNewValue As Integer)
    On Error GoTo wrong
    m_date = Reduce(Second(m_date), Minute(m_date), vNewValue, Day(m_date), Month(m_date), Year(m_date))
wrong:
End Property

Public Property Get TheDay() As Integer
    TheDay = Day(m_date)
End Property
Public Property Let TheDay(ByVal vNewValue As Integer)
    On Error GoTo wrong
    m_date = Reduce(Second(m_date), Minute(m_date), Hour(m_date), vNewValue, Month(m_date), Year(m_date))
wrong:
End Property

Public Property Get TheMonth() As Integer
    TheMonth = Month(m_date)
End Property
Public Property Let TheMonth(ByVal vNewValue As Integer)
    On Error GoTo wrong
    m_date = Reduce(Second(m_date), Minute(m_date), Hour(m_date), Day(m_date), vNewValue, Year(m_date))
wrong:
End Property

Public Property Get TheYear() As Integer
    TheYear = Year(m_date)
End Property
Public Property Let TheYear(ByVal vNewValue As Integer)
    On Error GoTo wrong
    m_date = Reduce(Second(m_date), Minute(m_date), Hour(m_date), Day(m_date), Month(m_date), vNewValue)
wrong:
End Property

Public Function AmericanDate() As String
    AmericanDate = "#" & Format(m_date, c_frmdateA) & "#"
End Function
Public Function DateString() As String
    DateString = Format(m_date, c_frmdate)
End Function
Public Function TimeString() As String
    TimeString = Format(m_date, c_frmtime)
End Function
Public Function TheWeekday() As Integer
    TheWeekday = WeekDay(m_date)
End Function
Public Function IsWeekend() As Boolean
    Select Case WeekDay(m_date)
    Case vbSunday
        IsWeekend = True
    Case vbSaturday
        IsWeekend = True
    Case Else
        IsWeekend = False
    End Select
End Function