viktturПроверьте (формула массива):
=СУММ(ЕСЛИ(ЕЧИСЛО(НАЙТИ($C18;$C$7:$C$14));D$7:D$14))
Или то же через СУММПРОИЗВ()

При такой формуле, может произойти дублирование, например если есть 5470/512 и 5470/51

Если всегда есть пробел, то надежнее (и быстрее :-)) так:

=СУММЕСЛИ($C$7:$C$14;"* "&$C18&" *";D$7:D$14)

Если нужно учитывать то, что код может оказаться в конце строки, то тогда так:

=CУММ(СУММЕСЛИ($C$7:$C$14;"* "&$C18&{" *";""};D$7:D$14))

Aster32Чтобы не заморачиваться со сложными формулами, можно использовать vba. В приложенном файле записана процедура, производящая вычисления в вашей таблице при нажатии на кнопку. Код автоматически учитывает, что данная таблица будет продолжаться вправо (добавление новых недель), а также то, что будет расти длина списка компьютеров и списка деталей. Однако код будет нуждаться в модификации, так как начальная строка списка деталей (в приложенном файле это строка 16) будет смещаться вниз по мере роста списка компьютеров. Либо разнесите список компьютеров и список деталей на разные листы, с соответствующей правкой кода.
И все это для того, чтобы избежать написания формулы состоящей из одной функции и трех параметров :-0

Сравните

=СУММЕСЛИ($C$7:$C$14;"* "&$C18&" *";D$7:D$14)

и


и добавьте ко второму предложения по возможным модификациям

+ то, что данный код тоже выдаст ошибочные результаты если один код является частью другого ;-)

Aster32авторСравните

=СУММЕСЛИ($C$7:$C$14;"* "&$C18&" *";D$7:D$14)

Настораживает, что в формуле диапазон указан с абсолютной адресацией. То есть, если исходная таблица будет расширена, а это так и будет, то все формулы нужно будет переписывать?

1) вы про какой из 3 диапазонов? У них разные векторы зафиксированы.

2) если таблица расширяется путем вставки строк или диапазон помечен как Список (XL2003) или как Таблица (XL2007+), то формула изменяется автоматически

3) ничто не мешает создать динамический именованную формулу: LRow=ПОИСКПОЗ("яяяя";$C:$C) и на листе писать так:
=СУММЕСЛИ($C$7:ИНДЕКС($C:$C;LRow);"* "&$C18&" *";D$7:ИНДЕКС($D:$D;LRow))
Можно и еще короче, но формула будет летучей:
=СУММЕСЛИ($C$7:ИНДЕКС($C:$C;LRow);"* "&$C18&" *";D$7)

_slan_KL (XL),


так сравнивать некорректно.

вот так логичнее:

=СУММЕСЛИ($C$7:$C$14;"* "&$C18&" *";D$7:D$14)

и

=DetailCalculate()


или надо сравнивать коды обеих функций :)
Нет, сравнивать надо именно сферу воздействия пользователя, т.е. работу, которую пользователь должен проделать для получения результата (написание, отладка, применение) ;-)

Формулы и VBA - языки программирования для пользователя

На листе код - формула
В VBA код - процедура

Другое дело, что каждый из них потом использует функции и команды запрограммированные создателем приложения на языках более высокого уровня.

Т.ч. можно еще сравнивать внутренний код СУММЕСЛИ и .Find()

Aster32,

Вообще-то я никого не уговариваю, а аргументирую свою точку зрения :)
Ваша последняя функция делает разговор о затратах на написание и поддержание бессмысленным, т.к. создает гораздо большую проблему со скоростью пересчета.

На моем компе для 1000 строк в БД полный пересчет (средн. для 5 попыток) занимает:

=СУММЕСЛИ($B$4:$B$1004;"* "&$I9&" *";C$4:C$1004) - 74 мсек

=detailcalc($I3,C$2) - 1334 мсек

viktturПолучается, СУММЕСЛИ определяет D$7 как бесконечный диапазон?

KL, почему формула названа летучей?

1) не бесконечный, а что-то типа [D7].Resize([$C$7:$C$14].Count)

2) в таком написании (начиная с версии 2002XP) формула становится летучей, т.к. не все ячейки влияющие на результат явно отражены в аргументах функции)

[quot KL (XL)3) ничто не мешает создать динамический именованную формулу: LRow=ПОИСКПОЗ("яяяя";$C:$C) и на листе писать так:
=СУММЕСЛИ($C$7:ИНДЕКС($C:$C;LRow);"* "&$C18&" *";D$7:ИНДЕКС($D:$D;LRow))
Можно и еще короче, но формула будет летучей:
=СУММЕСЛИ($C$7:ИНДЕКС($C:$C;LRow);"* "&$C18&" *";D$7)[/quot]

Кстати, в этом случае, лучше даже вместо имени использовать ячейку с формулой:

[A1]=ПОИСКПОЗ("яяяя";$C:$C)

и писать на листе:

=СУММЕСЛИ($C$7:ИНДЕКС($C:$C;$A$1);"* "&$C18&" *";D$7:ИНДЕКС($D:$D;$A$1))

это позволит значительно увеличить скорость пересчета.

viktturЕще один образовательный вопрос - многие ли функции умеют определять недописанное?
За исключением того, что все функции позволяют не писать 0 там, где требуется число или значение ЛОЖЬ [=ЕСЛИ(А1>0;1;)] [=ПОИСКПОЗ(1;{1;2;3};)] [=СУММ(1;;6)], и того, что некоторые функции позволяют опускать аргументы [=ЕСЛИ(А1>0;1)] [=ПОИСКПОЗ(1;{1;2;3})] ... :-)
... так навскидку, ничего похожего не припоминаю. Если припомню, отпишусь.