'Find Find Find
'коды, которые находят слово text и делают его жирным.
'Код с Selection:
Sub Макрос1()
With Selection.Find
    'Очистка
    .ClearFormatting
    .Replacement.ClearFormatting
    'Искомый текст.
    .Text = "text"
    'Текст на который меняем.
    'Если .Format = True, то меняется только форматирование.
    .Replacement.Text = ""
    'Сделать найденный текст жирным.
    .Replacement.Font.Bold = True
    'Направление поиска: если True - то в конец документа.
    'Если False - то в начало документа.
    .Forward = True
    'wdFindStop - поиск в выделенной области или
    'от места нахождения курсора до конца документа.
    'wdFindContinue - поиск по всему документу.
    'wdFindAsk - предлагается выбор:
    'продолжить поиск по всему документу или остановить
    .Wrap = wdFindStop
    'Определяет: производится замена текста или форматирования.
    'Если .Format = True и .Replacement.Text = "", то замена форматирования.
    'Если .Format = True и .Replacement.Text = "text2", то замена текста и форматирования.
    'Если .Format = False и .Replacement.Text = "", то удаление текста.
    'Если .Format = False и .Replacement.Text = "text2", то замена текста.
    .Format = True
    'С Match - смотрите флажки в диалоговом окне Найти и заменить.
    .MatchCase = False
    .MatchWholeWord = False
    .MatchWildcards = False
    .MatchSoundsLike = False
    .MatchAllWordForms = False
    'Здесь действие выполняется по замене.
    .Execute Replace:=wdReplaceAll
    'Очистка.
    .ClearFormatting
    .Replacement.ClearFormatting
    .Text = ""
End With
End Sub
Код с Content (в данном коде Content можно заменить Range):

Sub P2()
'Поиск и замена во всём документе.
With ActiveDocument.Content.Find
    .Text = "text"
    .Replacement.Text = ""
    .Replacement.Font.Bold = True
    .Format = True
    .Execute Replace:=wdReplaceAll
End With
End Sub