Private Sub CommandButton1_Click()
    ProcedureCode "CommandButton2_Click", _
      "Лист2", ThisWorkbook
End Sub

Private Sub ProcedureCode( _
  strProcedureName As String, _
  strModuleName As String, _
  wb As Workbook)
    Dim cm As CodeModule
    Dim lngStart As Long
    Dim lngCount As Long
  
    If fnProcedureExists(strProcedureName, _
      strModuleName, wb) Then
        Set cm = wb.VBProject.VBComponents(strModuleName).CodeModule
        
        lngStart = cm.ProcStartLine( _
          strProcedureName, vbext_pk_Proc)
        
        If lngStart >  0  Then
            lngCount = cm.ProcCountLines( _
              strProcedureName, vbext_pk_Proc)
            MsgBox (cm.Lines(lngStart, lngCount))
        End If
        
        Set cm = Nothing
    Else
        MsgBox ("Такой процедуры нет.")
    End If
End Sub

Private Function fnProcedureExists( _
  strProcedureName As String, _
  strModuleName As String, _
  wb As Workbook) As Boolean
    On Error Resume Next
    
    fnProcedureExists = wb.VBProject.VBComponents(strModuleName) _
      .CodeModule.ProcStartLine(strProcedureName, vbext_pk_Proc) <>  0 
End Function