Sub DeleteHiddenNames2()
Dim iPath As String, iFileName As String
Dim n As Name, Count As Integer
Dim WB As Workbook
    iPath = "C:\Temp\" 'укажите путь к папке
    iFileName = Dir(iPath & "*.xls") 'берём имя первого файла xls
    With Application
        .ScreenUpdating = False 'отключаем обноление экрана
        '.DisplayAlerts = False 'отключаем сообщения
        .Calculation = xlManual 'отключаем автоматический пересчёт
        .EnableEvents = False 'отключаем события
        Do While iFileName <> ""
            Set WB = Workbooks.Open(Filename:=iPath & iFileName, UpdateLinks:= 0 ) 'открываем файлы по очереди
            For Each n In WB.Names
                If Not n.Visible Then
                    n.Delete
                    Count = Count +  1 
                End If
            Next n
            WB.Close SaveChanges:=True 'закрываем, сохраняя изменения
            iFileName = Dir 'передача названия другого файла
        Loop
        .EnableEvents = True 'вкл
        .Calculation = xlAutomatic 'вкл
        .DisplayAlerts = True 'вкл
        .ScreenUpdating = True 'вкл
    End With
    MsgBox "Скрытые имена в количестве " & Count & " удалены!", vbInformation, "Удаление скрытых имён"
End Sub