DeggasadНедавно была одна задачка, с которой никто у нас можно сказать до конца не справился!
Есть ряд значений которым необходимо присвоить места (порядковые номера) по возврастанию, но только без пропуска мест, т.е. если значения повторяются, то они получают одинаковые места, но следующее место не выбрасывается, как делает например функция ранг(). Причём необходимо сделать это в одном столбце (желательно стандартными формулами), без использования макросов!
Несколько вариантов решения есть, но все в 2 столбца, а нужно было (или как бы это сказать - хотелось бы) в одном столбце.
В прилагаемом файле есть пример и найденные варианты решения.

В одном столбце можно, а нужно ли - судить тебе:

1-й способ
=СТРОКА(B14)-СТРОКА($B$13)
=СМЕЩ($D$13;РАНГ(B14;$B$14:$B$65536;1);0)

время пересчета в 1000 ячеек: 106,87 миллисек.
летучая (пересчет при любом изменении на листе): да
вспомогательные ячейки: да

2 -й способ
=ЕСЛИ(ЕНД(ПОИСКПОЗ(B14;$B$13:B13;0));СЧЁТЕСЛИ($B$14:$B$44;"="&B14)-1;0)
=СЧЁТЕСЛИ($B$14:$B$44;"<="&B14)-СУММЕСЛИ($B$14:$B$44;"<="&B14;$N$14:$N$44)

время пересчета в 1000 ячеек: 302,75 миллисек.
летучая (пересчет при любом изменении на листе): нет
вспомогательные ячейки: да

3-й способ
Матричная формула (ввод через CTRL+SHIFT+ENTER)
=ПОИСКПОЗ(B14;НАИМЕНЬШИЙ(ЕСЛИ(ЧАСТОТА($B$14:$B$44;$B$14:$B$44)>0;$B$14:$B$44);СТРОКА($B$14:$B$44)-СТРОКА($B$14)+1))

время пересчета в 1000 ячеек: 13191,72 миллисек.
летучая (пересчет при любом изменении на листе): нет
вспомогательные ячейки: нет

KL
[MVP - Microsoft Excel]

DeggasadА чем черевато что не летучая???
Вы свё время про это говорите, нужно ли чтобы она пересчитывалась при любых изменениях
Ведь если исходные данные меняешь она же пересчитывает.В абсолютном большинстве случаев нелетучая формула - лучше , так как пересчитывается только при изменениях в ячейках, задействованных, прямо или косвенно, в данной конкретной формуле.

Как я уже сказал ранее, летучая формула пересчитывает при любых изменениях на листе независимо от того, влияет ли изменение на результат или нет .

Летучесть обычно нужна, когда изменение влияющее на результат не провоцирует события Calculate (пересчет) автоматически как это было в формуле с XLM в другой теме.

Все формулы использующие функции СЛЧИС(); ТДАТА(); СЕГОДНЯ(); СМЕЩ(); ЯЧЕЙКА(); ДВССЫЛ(); ИНФОРМ(); ЯЧЕЙКА("Filename") летучи по определению.

Формулы также могут становиться летучими из-за превышения лимита в 65.536 зависимостей или в результате использования пользовательских функций (UDF) содержащих инструкцию Application.Volatile=True

Подробно о летучести в Excel можно прочесть здесь: http://www.decisionmodels.com/calcsecretsi.htm

KL
[MVP - Microsoft Excel]

Еще вариант в два столбца, довольно быстрый (120,24 миллисек. в 1000 ячеек) и не летучий:

=ЕСЛИ(СЧЁТЕСЛИ(B14:$B$14;B14)<2;B14)
=РАНГ(B14;$I$14:$I$44;1)

KL
[MVP - Microsoft Excel]