Public Function pdu2text(pdu As String, ByVal pduLen As Integer) As String
Dim i As Long, octet As Long, septet As Long, remainder As Long, divider As Long
Dim s As String

  remainder = 0
  For i = 0 To Len(pdu) \ 2 - 1
    s = "&H" & VBA.Mid$(pdu, i * 2 + 1, 2)
'    Debug.Print s
    octet = CByte(s)
    septet = (octet * 2 ^ (i Mod 7) + remainder) And 127
    divider = 2 ^ (7 - (i Mod 7))
    remainder = octet \ divider
    pdu2text = pdu2text & Chr(septet)
    If Len(pdu2text) = pduLen Then Exit For
    If (i Mod 7) = 6 Then
        pdu2text = pdu2text & Chr(remainder)
        remainder = 0
    End If
  Next i
  
  pdu2text = VBA.Replace(pdu2text, Chr(0), "")
  
End Function

Public Function txt2pdu(ByVal stxt As String) As String
Dim s As Long
Dim Y As Integer
Dim X As String
Dim Text As String
Dim out As String
Dim L As Long

    For Y = 1 To Len(stxt)
        X = Dec2Bin(Asc(Mid(stxt, Y, 1)), True)
        'If X = "100000" Then X = "0100000"
        Text = X & Text
    Next Y
    'Debug.Print Text
    L = VBA.Len(Text)
    s = L - 7
    If s = 0 Then s = 1
    out = Bin2Hex(Mid(Text, s, 8))
    Do Until s <= 8
        s = s - 8
        out = out & Bin2Hex(Mid(Text, s, 8))
    Loop
    out = out & Bin2Hex(Mid(Text, 1, s - 1))
    'Debug.Print out
    
    X = Hex(Len(stxt))
    If Len(X) = 1 Then
        X = "0" & X
    End If
    'Debug.Print X & out
    txt2pdu = X & out
    
End Function

Public Function Dec2Bin(ByVal nDec As Integer, Optional ByVal OldVersion As Boolean = False) As String
'This function is the same then Hex2Bin,
'     but it has been copied to speed up proce
'     ss
Dim i As Integer
Dim j As Integer
Dim sHex As String
Const HexChar As String = "0123456789ABCDEF"
    
    sHex = Hex(nDec) 'That the only part that is different

    For i = 1 To Len(sHex)
        nDec = InStr(1, HexChar, Mid(sHex, i, 1)) - 1
        For j = 3 To 0 Step -1
            Dec2Bin = Dec2Bin & nDec \ 2 ^ j
            nDec = nDec Mod 2 ^ j
        Next j
    Next i
    If OldVersion Then
        'Remove the first unused 0
        i = InStr(1, Dec2Bin, "1")
        If i <> 0 Then Dec2Bin = Mid(Dec2Bin, i)
        If Len(Dec2Bin) = 6 Then Dec2Bin = "0" & Dec2Bin
    Else
        Dec2Bin = Format(Dec2Bin, "00000000")
    End If
    
End Function

Public Function Bin2Hex(ByVal sBin As String) As String
Dim i As Integer
Dim nDec As Long
    
    sBin = String(4 - Len(sBin) Mod 4, "0") & sBin 'Add zero to complete Byte
    For i = 1 To Len(sBin)
        nDec = nDec + CInt(Mid(sBin, Len(sBin) - i + 1, 1)) * 2 ^ (i - 1)
    Next i
    Bin2Hex = Hex(nDec)
    If Len(Bin2Hex) Mod 2 = 1 Then Bin2Hex = "0" & Bin2Hex
    
End Function