Option Explicit

Const WM_NCACTIVATE = &H86
Private Const GWL_WNDPROC As Long = (-4)
Private m_frmA As Form
Private m_lDefWindowProc As Long

Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Private Declare Function CallWindowProc Lib "user32" Alias "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal hWnd As Long, ByVal uMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long

Public Sub SubClassForNoLostFocus(frmA As Form)
    Dim hWnd As Long
    hWnd = frmA.hWnd 'get handler
    Set m_frmA = frmA

    m_lDefWindowProc = SetWindowLong(hWnd, GWL_WNDPROC, AddressOf WndProc)
End Sub

Public Sub UnSubClassForNoLostFocus(frmA As Form)
    Dim hWnd As Long
    hWnd = frmA.hWnd 'get handler

    SetWindowLong hWnd, GWL_WNDPROC, m_lDefWindowProc

    Set m_frmA = Nothing
End Sub

Private Function WndProc(ByVal hWnd As Long, ByVal lMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
    Dim lResult As Long

    If hWnd = m_frmA.hWnd Then
        Select Case lMsg 
            Case WM_NCACTIVATE
                wParam = 1
                lResult = CallWindowProc(m_lDefWindowProc, hWnd, lMsg, wParam, lParam)
            Case Else
                lResult = CallWindowProc(m_lDefWindowProc, hWnd, lMsg, wParam, lParam)
        End Select
    End If

    WndProc = lResult
End Function