.fMask = SEE_MASK_NOCLOSEPROCESS 

Public Function ExecuteProcess(ByVal FilePath As String, ByVal hwnd As Long, _
 ByVal nShow As Long, Optional lpParameters As String = "", _
 Optional LaunchElevated As Boolean = False, _
 Optional useDoEvent As Boolean = False) As ExecuteStatus 'nShow - напр.SW_SHOWNORMAL
 
  'useDoEvent -использует цикл с DoEvent вместо WaitForSingleObject
 
  Dim ExecInfo As SHELLEXECUTEINFO
  Dim lExitCode As Long

  With ExecInfo
    ' Set up the structure.
    .cbSize = Len(ExecInfo)
    .fMask = SEE_MASK_NOCLOSEPROCESS ' SEE_MASK_DEFAULT
    .lpFile = FilePath
    .nShow = nShow
    .lpDirectory = ExtractDirectoryFromPath(FilePath)
    .lpParameters = lpParameters
    .hwnd = hwnd

    ' On Microsoft Windows Vista and later, one can use runas instead of Open, in order to execute the
    ' process as an elevated process. In that case, the user will be asked whether he or she wants to
    ' run the process as an administrator.
    If LaunchElevated = True Then
      .lpVerb = "runas"
    Else
      .lpVerb = "Open"
    End If
  End With

  If ShellExecuteEx(ExecInfo) Then
    If useDoEvent Then
      Do
        'Get the status of the process
        GetExitCodeProcess ExecInfo.hProcess, lExitCode
        DoEvents
        'Loop while the process is active
      Loop While lExitCode = STILL_ACTIVE
    Else
      Call WaitForSingleObject(ExecInfo.hProcess, INFINITE)
    End If
    If GetExitCodeProcess(ExecInfo.hProcess, lExitCode) <> 0 Then
      If lExitCode = 0 Then
        ExecuteProcess = res_OK
      Else
        ExecuteProcess = res_FAILED
      End If
    Else
      ExecuteProcess = res_FAILED
    End If
    Call CloseHandle(ExecInfo.hProcess)
  Else
    ExecuteProcess = res_CANCEL
  End If
End Function