Option Explicit

Private Type GdiplusStartupInput
   GdiplusVersion As Long
   DebugEventCallback As Long
   SuppressBackgroundThread As Long
   SuppressExternalCodecs As Long
End Type

' GDI+ Status
Private Enum GpStatus
   OK =  0 
   GenericError =  1 
   InvalidParameter =  2 
   OutOfMemory =  3 
   ObjectBusy =  4 
   InsufficientBuffer =  5 
   NotImplemented =  6 
   Win32Error =  7 
   WrongState =  8 
   Aborted =  9 
   FileNotFound =  10 
   ValueOverflow =  11 
   AccessDenied =  12 
   UnknownImageFormat =  13 
   FontFamilyNotFound =  14 
   FontStyleNotFound =  15 
   NotTrueTypeFont =  16 
   UnsupportedGdiplusVersion =  17 
   GdiplusNotInitialized =  18 
   PropertyNotFound =  19 
   PropertyNotSupported =  20 
   ProfileNotFound =  21 
End Enum

Private Declare Function GdiplusStartup Lib "gdiplus" ( _
   rToken As Long, rInput As GdiplusStartupInput, pvOutput As Any) As GpStatus
Private Declare Sub GdiplusShutdown Lib "gdiplus" ( _
   ByVal Token As Long)

Private Declare Function GdipCreateBitmapFromFile Lib "gdiplus" ( _
   ByVal FileNamePtr As Long, nBitmap As Long) As GpStatus
Private Declare Function GdipDisposeImage Lib "gdiplus" ( _
   ByVal nImage As Long) As GpStatus

Private Enum PixelFormats
   PixelFormatUndefined = &H0&
   PixelFormatDontCare = PixelFormatUndefined
   PixelFormatMax = &HF&
   PixelFormat1_8 = &H100&
   PixelFormat4_8 = &H400&
   PixelFormat8_8 = &H800&
   PixelFormat16_8 = &H1000&
   PixelFormat24_8 = &H1800&
   PixelFormat32_8 = &H2000&
   PixelFormat48_8 = &H3000&
   PixelFormat64_8 = &H4000&
   PixelFormat16bppRGB555 = &H21005
   PixelFormat16bppRGB565 = &H21006
   PixelFormat16bppGrayScale = &H101004
   PixelFormat16bppARGB1555 = &H61007
   PixelFormat24bppRGB = &H21808
   PixelFormat32bppRGB = &H22009
   PixelFormat32bppARGB = &H26200A
   PixelFormat32bppPARGB = &HD200B
   PixelFormat48bppRGB = &H10300C
   PixelFormat64bppARGB = &H34400D
   PixelFormat64bppPARGB = &H1C400E
   PixelFormatGDI = &H20000
   PixelFormat1bppIndexed = &H30101
   PixelFormat4bppIndexed = &H30402
   PixelFormat8bppIndexed = &H30803
   PixelFormatAlpha = &H40000
   PixelFormatIndexed = &H10000
   PixelFormatPAlpha = &H80000
   PixelFormatExtended = &H100000
   PixelFormatCanonical = &H200000
End Enum

Private Declare Function GdipGetImagePixelFormat Lib "gdiplus" ( _
   ByVal nImage As Long, PixelFormat As PixelFormats) As GpStatus

Private Declare Function GdipGetImageWidth Lib "gdiplus" ( _
   ByVal nImage As Long, Width As Long) As Long
Private Declare Function GdipGetImageHeight Lib "gdiplus" ( _
   ByVal nImage As Long, Height As Long) As Long

Private Sub Command1_Click()
 Dim GdipSession As Long
 Dim gpsi As GdiplusStartupInput
 Dim gpsResult As GpStatus
 Dim nBitmap As Long
 Dim PxFmt As PixelFormats
 Dim sPxFmt As String
 Dim lWidth As Long, lHeight As Long
 
 With gpsi
    .GdiplusVersion =  1 
    .DebugEventCallback =  0 
    .SuppressBackgroundThread =  0 
    .SuppressExternalCodecs =  1 
 End With
 
 gpsResult = GdiplusStartup(GdipSession, gpsi, ByVal  0 &)
 If gpsResult <> OK Then
    MsgBox "GDI+ Initialization Failed. Error code " & gpsResult, _
           vbCritical, Me.Caption
    Exit Sub
 End If

 gpsResult = GdipCreateBitmapFromFile(StrPtr("F:\werqw1.png"), nBitmap)
 If gpsResult = OK Then
    gpsResult = GdipGetImageWidth(nBitmap, lWidth)
    If gpsResult = OK Then
       Debug.Print "Image width is " & lWidth & " pixel(s)"
    Else
       MsgBox "Image width was not retrieved. Error code " & gpsResult, _
              vbExclamation, Me.Caption
    End If
    
    gpsResult = GdipGetImageHeight(nBitmap, lHeight)
    If gpsResult = OK Then
       Debug.Print "Image height is " & lHeight & " pixel(s)"
    Else
       MsgBox "Image Height was not retrieved. Error code " & gpsResult, _
              vbExclamation, Me.Caption
    End If
    
    gpsResult = GdipGetImagePixelFormat(nBitmap, PxFmt)
    If gpsResult = OK Then
       Select Case PxFmt
       Case PixelFormatUndefined: sPxFmt = "Undefined"
       Case PixelFormatMax: sPxFmt = "Max"
       Case PixelFormat1_8: sPxFmt = "1_8"
       Case PixelFormat4_8: sPxFmt = "4_8"
       Case PixelFormat8_8: sPxFmt = "8_8"
       Case PixelFormat16_8: sPxFmt = "16_8"
       Case PixelFormat24_8: sPxFmt = "24_8"
       Case PixelFormat32_8: sPxFmt = "32_8"
       Case PixelFormat48_8: sPxFmt = "48_8"
       Case PixelFormat64_8: sPxFmt = "64_8"
       Case PixelFormat16bppRGB555: sPxFmt = "Undefined"
       Case PixelFormat16bppRGB565: sPxFmt = "16bppRGB565"
       Case PixelFormat16bppGrayScale: sPxFmt = "16bppGrayScale"
       Case PixelFormat16bppARGB1555: sPxFmt = "16bppARGB1555"
       Case PixelFormat24bppRGB: sPxFmt = "24bppRGB"
       Case PixelFormat32bppRGB: sPxFmt = "32bppRGB"
       Case PixelFormat32bppARGB: sPxFmt = "32bppARGB"
       Case PixelFormat32bppPARGB: sPxFmt = "32bppPARGB"
       Case PixelFormat48bppRGB: sPxFmt = "48bppRGB"
       Case PixelFormat64bppARGB: sPxFmt = "64bppARGB"
       Case PixelFormat64bppPARGB: sPxFmt = "64bppPARGB"
       Case PixelFormatGDI: sPxFmt = "GDI"
       Case PixelFormat1bppIndexed: sPxFmt = "1bppIndexed"
       Case PixelFormat4bppIndexed: sPxFmt = "4bppIndexed"
       Case PixelFormat8bppIndexed: sPxFmt = "8bppIndexed"
       Case PixelFormatAlpha: sPxFmt = "Alpha"
       Case PixelFormatIndexed: sPxFmt = "Indexed"
       Case PixelFormatPAlpha: sPxFmt = "PAlpha"
       Case PixelFormatExtended: sPxFmt = "Extended"
       Case PixelFormatCanonical: sPxFmt = "Canonical"
       Case Else: sPxFmt = "Unknown"
       End Select
       Debug.Print "Pixel format is " & sPxFmt
    Else
       MsgBox "Image format was not retrieved. Error code " & gpsResult, _
              vbExclamation, Me.Caption
    End If
 
    GdipDisposeImage nBitmap
 Else
    MsgBox "Image was not loaded. Error code " & gpsResult, _
           vbExclamation, Me.Caption
 End If
 
 GdiplusShutdown GdipSession
End Sub

Case PixelFormat16bppRGB555: sPxFmt = "Undefined"

Case PixelFormat16bppRGB555: sPxFmt = "16bppRGB555"