Лучше один ini файл с разделами. Ещё лучше, если он хранится в том же каталоге, где и .exe файл программы, а не в системном каталоге. В этом случае можно иметь несколько копий программы с разными натсройками в разных каталогах на одной машине.

В своё время я себе сделал вот такой класс

TFileCfg = class
protected
CfgFile:TIniFile;
function GetFileName:string; virtual;
public
FileName:string;
StartPath:string;
constructor Create(Path:string);
procedure LoadData;
procedure SaveData;
procedure LoadCfg; virtual; abstract;
procedure SaveCfg; virtual; abstract;
procedure LoadFromFile(const FileName:string);
procedure SaveToFile(const FileName:string);
end;

constructor TFileCfg.Create(Path:string);
begin
Inherited Create;
StartPath:=ExtractFilePath(Application.ExeName);
if StartPath='' then GetDir(0,StartPath);
if copy(StartPath,Length(StartPath),1)<>'\' then StartPath:=StartPath+'\';
if Path='' then Path:=StartPath;
if copy(Path,Length(Path),1)<>'\' then Path:=Path+'\';
FileName:=Path+GetFileName;
LoadData;
end;

function TFileCfg.GetFileName:string;
begin
Result:=ChangeFileExt(ExtractFileName(Application.ExeName),'.ini');
end;

procedure TFileCfg.LoadData;
begin
CfgFile:=TIniFile.Create(FileName);
try LoadCfg;
finally CfgFile.Free; end;
end;

procedure TFileCfg.SaveData;
begin
CfgFile:=TIniFile.Create(FileName);
try SaveCfg;
finally CfgFile.Free; end;
end;

procedure TFileCfg.LoadFromFile(const FileName:string);
begin
Self.FileName:=FileName;
LoadData;
end;

procedure TFileCfg.SaveToFile(const FileName:string);
begin
Self.FileName:=FileName;
SaveData;
end;

в программах потом создаётся класс-наследник, в котором прописываются необходимые поля-параметры и перекрываются две процедуры LoadCfg и SaveCfg

В обработчике события OnCreate главной формы создаёте экземпляр этого класса. Если передать в Create пустую строку Path, то, как видно из текста процедуры, он возмёт путь от Exe файла. Если не перекрывать функцию GetFileName, то имя ini файла будет точно такое же, как и у exe файла.

В программе, когда нужно сохранить параметры, просто вызываете SaveData (но не SaveCfg!!!).

Небольшой пример использования

TCourierConfig = class (TFileCfg)
public
ServerName:string;
BaseName:string;
UserName:string;
Password:string;
AutoLogin:boolean;
FullConnectString:boolean;
ConnectString:string;
PacketSize:integer;
DocStartDate:TDateTime;
CodePeriod:integer;
fFullScreen:boolean;


OrderTemp:string;
OtvodTemp:string;
PathListText:string;

procedure LoadCfg; override;
procedure SaveCfg; override;
end;

procedure TCourierConfig.LoadCfg;
begin
with CfgFile do begin
ServerName:=ReadString('Courier30','ServerName','localhost');
BaseName:=ReadString('Courier30','BaseName','Courier30');
UserName:=ReadString('Courier30','UserName','CoureirOper');
Password:=ReadString('Courier30','Password','courier');
AutoLogin:=ReadBool('Courier30','AutoLogin',false);
FullConnectString:=ReadBool('Courier30','FullConnectString',false);
ConnectString:=ReadString('Courier30','ConnectString',
'Provider=SQLOLEDB.1;Password=Courier;Persist Security Info=True;User ID=CourierOper;Initial Catalog=Courier30;Data Source=DIMKA;Use Procedure for Prepare=1;Auto Translate=True;Packet Size=8192;Workstation ID=DIMKA');
PacketSize:=ReadInteger('Courier30','PacketSize',8192);
DocStartDate:=StrToDate(ReadString('Courier30','DocStartDate','1.01.2003'));
CodePeriod:=ReadInteger('Courier30','CodePeriod',prEtotGod);
fFullScreen:=ReadBool('Courier30','FullScreen',false);

OrderTemp:=ReadString('Templates','OrderTemp','');
OtvodTemp:=ReadString('Templates','OtvodTemp','');
PathListText:=ReadString('Templates','PathListText','');

end;
end;

procedure TCourierConfig.SaveCfg;
begin
with CfgFile do begin
WriteString('Courier30','ServerName',ServerName);
WriteString('Courier30','BaseName',BaseName);
WriteString('Courier30','UserName',UserName);
WriteString('Courier30','Password',Password);
WriteBool('Courier30','AutoLogin',AutoLogin);
WriteBool('Courier30','FullConnectString',FullConnectString);
WriteString('Courier30','ConnectString',ConnectString);
WriteInteger('Courier30','PacketSize',PacketSize);
WriteString('Courier30','DocStartDate',DateToStr(DocStartDate));
WriteInteger('Courier30','CodePeriod',CodePeriod);
WriteBool('Courier30','FullScreen',fFullScreen);

WriteString('Templates','OrderTemp',OrderTemp);
WriteString('Templates','OtvodTemp',OtvodTemp);
WriteString('Templates','PathListText',PathListText);
end;
end;