Ссылки на метод объекта не эквивалентны ссылкам на процедуру.
Ссылка на процедуру представляет собой 32 битный указатель на место расположения машинного кода процедуры в сегменте кода программы, т.е. число.
Ссылка на метод объекта - пара чисел, первое из которых - адрес кода самого метода в классе объекта; а второе - адрес объекта, для которого вызывается метод. Для хранения ссылок на метод в DelphiPascal существует тип TMethod:
1.
2.
3.
4.
type
TMethod = record
Code, Data: Pointer;
end;
Метод TObject.MethodAddress возвращает как раз значение соответствующее TMethod.Code.
Т.о., чтобы сохранить где-то ссылку на метод объекта, необходимо объявить переменную типа TMethod, и заполнить ее поля:
1.
2.
3.
4.
5.
6.
var MyMethod: TMethod;
...
MyMethod.Data := Pointer(SomeObjectHasMethod);
MyMethod.Code := SomeObjectHasMethod.MethodAddress('SomeUsefullMethod');
(кстати значение Event`ов представляют собой тоже TMethod, только типизированные )
Чтобы использовать сохраненное ранее в MyMethod значение для вызова метода, необходимо объявить в секции деклараций событийный тип соответствующий структуре сохраненного метода и привести к нему MyMethod.
Например:
1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
11.
12.
13.
14.
15.
16.
17.
18.
19.
20.
21.
22.
23.
24.
25.
26.
27.
28.
29.
30.
31.
32.
33.
34.
35.
36.
37.
38.
39.
40.
41.
42.
43.
44.
45.
46.
47.
48.
49.
50.
51.
52.
53.
54.
55.
56.
57.
58.
59.
60.
61.
62.
63.
64.
65.
66.
67.
68.
69.
70.
71.
72.
73.
unit Unit1;
interface
uses
Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
Dialogs, StdCtrls;
type
TUsefulMethod = procedure (Param: String) of object;
TForm1 = class(TForm)
Button1: TButton;
procedure Button1Click(Sender: TObject);
private
{ Private declarations }
MyMethod: TMethod;
public
{ Public declarations }
procedure StoreMethod(MethodIndex: Integer);
procedure CallStoredMethod();
published
procedure UsefulMethod1(Param: String);
procedure UsefulMethod2(Param: String);
end;
var
Form1: TForm1;
implementation
uses StrUtils;
{$R *.dfm}
{ TForm1 }
procedure TForm1.CallStoredMethod;
begin
if (MyMethod.Data <> nil) and (MyMethod.Code <> nil) then
begin
TUsefulMethod(MyMethod)('text for caption');
end;//if
end;
procedure TForm1.StoreMethod(MethodIndex: Integer);
begin
MyMethod.Data := Self;
if MethodIndex = 0 then
MyMethod.Code := MethodAddress('UsefulMethod1')
else
MyMethod.Code := MethodAddress('UsefulMethod2');
end;
procedure TForm1.UsefulMethod1(Param: String);
begin
Caption := Param;
end;
procedure TForm1.UsefulMethod2(Param: String);
begin
Caption := ReverseString(Param);
end;
procedure TForm1.Button1Click(Sender: TObject);
begin
{ меняем метод который вызывается при нажатии кнопки }
if (Tag = 0 ) then Tag := 1 else Tag := 0 ;
StoreMethod(Tag);
CallStoredMethod;
end;
end.
Обрати внимание, что UsefulMethod1 и UsefulMethod2 объявлены как published, иначе MethodAddress возвратит nil;
