function CreateSinglePageFromBitmap(const APDFFileName: string; APageWidth: Integer; ABitmap: TBitmap): Boolean;
type
  TPDFDocumentSaveOption = (dsoIncremental = 1, dsoNoIncremental = 2, dsoRemoveSecurity = 3);
const
  DEF_MAGICMULTIPLIER = 100.0 / 35.3;    // GRV possibly A4 format
var
  PDFBitmap: TPDFBitmap;
  PDFPageObject: TPDFPageObject;
  PDFDocument: TPDFDocument;
  PDFPage: TPDFPage;
  DocumentEngine: TPDFDocumentEngine;
  FirstScan: Pointer;
  FileStream: TFileStream;
  FileWrite: TPDFFileWriteEx;
  Bitmap: TBitmap;
  Delta: Double;
  LocalWidth: Double;
  LocalHeight: Double;

  procedure FlipVertical(ASource, ADest: TBitmap);   // GRV function needs to be checked
  var
    SourceRect, DestRect: TRect;
  begin
    ADest.PixelFormat := ASource.PixelFormat;
    ADest.SetSize(ASource.Width, ASource.Height);
    DestRect := Bounds(0, 0, ASource.Width, ASource.Height);
    SourceRect := Bounds(0, ASource.Height, ASource.Width, 0);
    ADest.Canvas.CopyRect(DestRect, ASource.Canvas, SourceRect)
  end;

begin
  Result := False;
  if (APageWidth > 0) and (ABitmap.PixelFormat = pf32bit) then
  begin
    DocumentEngine := TPDFDocumentEngine.Create;
    Bitmap := TBitmap.Create;
    FileStream := TFileStream.Create(APDFFileName, fmCreate or fmShareDenyWrite);
    with DocumentEngine do
      try
        if not Initialized or not CreateDocument then
          Exit;
        Delta := ABitmap.Width / ABitmap.Height;
        LocalWidth := APageWidth * DEF_MAGICMULTIPLIER;
        LocalHeight := LocalWidth / Delta;
        FlipVertical(ABitmap, Bitmap);
        PDFDocument := Document;
        with Functions do
        begin
          PDFPage := PageNew(PDFDocument, 0, LocalWidth, LocalHeight);
          PDFPageObject := NewImageObject(PDFDocument);
          FirstScan := Bitmap.ScanLine[Bitmap.Height - 1];
          PDFBitmap := BitmapCreateEx(Bitmap.Width, Bitmap.Height, 3, FirstScan, Bitmap.Width * 4);             // GRV possibly 4 is pf32bit
          ImageObjSetBitmap(@PDFPage, 1, PDFPageObject, PDFBitmap);
          if ImageObjSetMatrix(PDFPageObject, 1, 0, 0, 1, 0, 0) <> 0 then
          begin
            PageObjTransform(PDFPageObject, LocalWidth, 0, 0, LocalHeight, 0, 0);
            PageInsertObject(PDFPage, PDFPageObject);
            PageGenerateContent(PDFPage);
            with FileWrite do
            begin
              Inner.Version := 1;
              Inner.WriteBlock := @WriteBlockToStream;
              Stream := FileStream
            end;
            Result := SaveAsCopy(PDFDocument, @FileWrite, Ord(dsoRemoveSecurity)) <> 0
          end
        end
      finally
        FreeAndNil(DocumentEngine);
        FreeAndNil(Bitmap);
        FreeAndNil(FileStream)
      end
  end
end;