function _resetstkoflw: Boolean;
const
  MIN_STACK_REQ_WINNT = 2; // in pages

var
  pStack, pStackBase, pMaxGuard, pMinGuard: PAddress;
  mbi: TMemoryBasicInformation;
  si: TSystemInfo;
  PageSize: DWORD;
  RegionSize: DWORD;
  flOldProtect: DWORD;
  StackSizeInBytes: ULONG;
begin
  Result := False;
  pStack := GetStackPointer;

  // Find the base of the stack.
  if VirtualQuery(pStack, mbi, SizeOf(mbi)) = 0 then
    Exit;

  pStackBase := PAddress(mbi.AllocationBase);

  GetSystemInfo(si);
  PageSize := si.dwPageSize;
  RegionSize := 0;
  StackSizeInBytes := 0;               // Indicate just querying
  if Pointer(@GSetThreadStackGuarantee) = nil then
  begin
    GSetThreadStackGuarantee := GetProcAddress(LibKernel32, 'SetThreadStackGuarantee');
    if not Assigned(@GSetThreadStackGuarantee) then
      GSetThreadStackGuarantee := Pointer(1);
  end;
  if AssignedEx(Pointer(@GSetThreadStackGuarantee)) then
  begin
    if GSetThreadStackGuarantee(StackSizeInBytes) then
      RegionSize := StackSizeInBytes;
  end;

  {$R-}
  {$Q-}
  // Silence prefast about overflow/underflow
  RegionSize := PtrUInt(RegionSize + PageSize - 1) and (not PtrUInt(PageSize - 1));
  {$IFDEF OVERFLOWCHECKS_ON}{$Q+}{$ENDIF}
  {$IFDEF RANGECHECKS_ON}{$R+}{$ENDIF}

  //
  // If there is a stack guarantee (RegionSize nonzero), then increase
  // our guard page size by 1 so that even a subsequent fault that occurs
  // midway (instead of at the beginning) through the first guard page
  // will have the extra page to preserve the guarantee.
  //

  if RegionSize <> 0 then
    RegionSize := RegionSize + PageSize;

  if RegionSize < MIN_STACK_REQ_WINNT * PageSize then
    RegionSize := MIN_STACK_REQ_WINNT * PageSize;

  //
  // Find the page(s) just below where the stack pointer currently points.
  // This is the highest potential guard page.
  //

  {$R-}
  {$Q-}
  pMaxGuard := Pointer((PtrUInt(pStack) and (not (PtrUInt(PageSize) - 1))) - RegionSize);
  {$IFDEF OVERFLOWCHECKS_ON}{$Q+}{$ENDIF}
  {$IFDEF RANGECHECKS_ON}{$R+}{$ENDIF}

  //
  // If the potential guard page is too close to the start of the stack
  // region, abandon the reset effort for lack of space.  Win9x has a
  // larger reserved stack requirement.
  //

  pMinGuard := pStackBase + PageSize;

  if pMaxGuard < pMinGuard then
    Exit;

  // Set the new guard page just below the current stack page.

  if (VirtualAlloc(pMaxGuard, RegionSize, MEM_COMMIT, PAGE_READWRITE) = nil) or
     (not VirtualProtect(pMaxGuard, RegionSize, PAGE_READWRITE or PAGE_GUARD, flOldProtect)) then
    Exit;

  Result := True;
end;

NeedReset := False;
try
  Recursive(Recurse);
except
  on EStackOverflow do
  begin
    // Здесь нужно использовать минимум стека,
	// потому что у нас есть всего одна страница (4 кб).
    // Тут _resetstkoflw вызывать нельзя, 
	// потому что стек ещё не раскручен.
	// В настоящее время мы выполняемся в том месте,
	// куда нужно поместить GUARD-страницу, 
	// т.е. сейчас это сделать невозможно.
    // Поэтому вместо этого просто отметимся.
    NeedReset := True;
  end;
end;

// А здесь стек уже отмотался назад 
// и у нас есть гораздо больше места.
// Последняя страница теперь свободна 
// и её можно конвертировать в GUARD.
if NeedReset and (ac >= 2) then
  Result := _resetstkoflw;

// Если _resetstkoflw не смог создать GUARD-страницу,
// то дальнейшее выполнение небезопасно.
// Нужно максимально быстро корректно выйти из приложения.
if not Result then
begin
  Halt(3);
  Exit;
end;